Here's an alternative I've been playing with: 
package Regexp::Simple;

use overload;
use Parse::RecDescent;

local $/;
my $translate = Parse::RecDescent->new(<DATA>);

sub import {
        overload::constant qr => sub {
                return $translate->pattern($_[0]);
        }
}

1;

__DATA__
{ sub wrap { "(?:$_[0])".($_[1]||"") } }

pattern: element(s)         { join '', @{$item{element}} }

element: 'start_of_line'    { '^' }
       | 'whitespace'       { '\\s' }
       | 'digit'            { '\\d' }
       | 'non_digit'        { '\\D' }
       | 'literal' subpat   { wrap $item{subpat} }
       | 'optional' subpat  { wrap $item{subpat}, '?' }
       | 'many' subpat      { wrap $item{subpat}, '+' }
       | 'any' subpatlist   { wrap join "|", @{$item{subpatlist}} }
       | 'remember' subpat  { "($item{subpat})" }
       | <perl_quotelike>   { quotemeta $item[1][2] }

       # etc. as necessary

subpat: '(' pattern ')'     { $item[2] }

subpatlist: '(' pattern(s /,/) ')'
                            { $item[2] }

[download]

Then your example would become: 

use Regexp::Simple;

my $re = qr{
        start_of_line
        literal("1998/10/08")
        optional( whitespace )
        literal("[")
        remember( many( any( ":", digit ) ) )
        non_digit
};

if ('1998/10/08 [11:10]' =~ m/$re/) {
   print "Found a match at time $1!\n";
}

[download]
Since we all seem to be converging, I'll be happy collaborate (I have many more ideas for this module than those shown above above and it would be great to have someone else share the implementation effort.

Send me some email if either (or both) of you are interested.

And, yes, the Regexp:: namespace is an abomination.
But it's the standard abomination for Perl 5, so we should use it.

Damian

In reply to Re: Pondering Regex::English by TheDamian
in thread Pondering Regex::English by chromatic

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.