G'day namelkcip,

Welcome to the monastery.

Here's how you can use $/ to get each "object ..." as a record; specify which fields you want; and ignore fields (e.g. description) which don't exist in any given object.

Note how $/ is localised within an anonymous block. This makes $/ = "\nobject" a temporary value which only affects the while (<DATA>) {...} loop; elsewhere in your script, $/ will have its default value. See "Temporary Values via local()" for more details. 

#!/usr/bin/env perl

use strict;
use warnings;

my @objects;
my @fields = qw{network host description};

{
    local $/ = "\nobject";

    while (<DATA>) {
        my %object;

        for my $field (@fields) {
            / $field \s ( .*? ) $ /mx and $object{$field} = $1;
        }

        push @objects, \%object if keys %object;
    }
}

use Data::Dump;
dd \@objects;

__DATA__
object network Microsoft.Lync.Host.3
 host 138.108.25.111
 description Help Desk Ticket #476739
object network Microsoft.Lync.Host.4
 host 138.108.25.112
 description Help Desk Ticket #476739
object network Microsoft.Lync.Host.5
 host 138.108.25.113
 description Help Desk Ticket #476739
object network Microsoft.Lync.Host.6

[download]

Output:

[
  {
    description => "Help Desk Ticket #476739",
    host => "138.108.25.111",
    network => "Microsoft.Lync.Host.3",
  },
  {
    description => "Help Desk Ticket #476739",
    host => "138.108.25.112",
    network => "Microsoft.Lync.Host.4",
  },
  {
    description => "Help Desk Ticket #476739",
    host => "138.108.25.113",
    network => "Microsoft.Lync.Host.5",
  },
  { network => "Microsoft.Lync.Host.6" },
]

[download]

-- Ken

In reply to Re: Extract Data Between Lines by kcott
in thread Extract Data Between Lines by namelkcip

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.