If you don't like it … use a more "modern" module from CPAN.

This is the raison d'être of the DateTime project:  to get right what a plethora of other Perl date and time modules got wrong—or wrongish. The noble and ambitious purpose of the DateTime project and its suite of modules is explained by the project's leader, Dave Rolsky, in his 2003 Perl.com article titled The Many Dates and Times of Perl.

Here's a short Perl script that demonstrates using the DateTime module to compute the last day of the month for a given day of the week—a generalization of the subject of this thread. Notice the dearth of explanatory comments in the script. They're not really needed due to the clarity of the method and parameter names. My choices of variable names flowed naturally and easily from the method names.

use strict;
use warnings;

use DateTime;

@ARGV == 3 or die "Usage: perl $0 <day_of_week> <month> <year>\n";

my $day_of_week = shift; # (1 is Monday, 7 is Sunday)
my $month       = shift;
my $year        = shift;

$day_of_week =~ m/^[1-7]$/ or die "Invalid day of week: $day_of_week\n
+";

$month =~ m/^(?:[1-9]|1[012])$/ or die "Invalid month: $month\n";

print last_day_of_week_of_month($day_of_week, $month, $year), "\n";

exit 0;

sub last_day_of_week_of_month {
    my $day_of_week = shift; # (1 is Monday, 7 is Sunday)
    my $month       = shift;
    my $year        = shift;

    my $last_day_of_month
        = DateTime->last_day_of_month( year => $year, month => $month 
+);

    my $day_of_week_of_last_day_of_month
        = $last_day_of_month->day_of_week();

    my $last_day_of_week_of_month
        = $last_day_of_month->day() -
          (($day_of_week_of_last_day_of_month - $day_of_week) % 7);

    return $last_day_of_week_of_month;
}

[download]

Update:  Changed the name of the function from get_last_day_of_week_of_month to last_day_of_week_of_month to conform to the standard DateTime naming convention.

In reply to Re^6: Gettting the last Friday of every month using Time::Piece # evolution of old modules by Jim
in thread Gettting the last Friday of every month using Time::Piece by Anonymous Monk

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.