The following tool takes out having to do all the hard, error-prone work. 
use strict;
use warnings;

use Encode qw( encode decode );

{
   my @charset =
      grep $_ ne "\x{FFFD}",
         map decode('cp1252', chr($_)),
            0x00..0xFF;

   my %map;
   for my $dec (@charset) {
      my $enc =
         encode 'UTF-8',
            decode 'cp1252',
               encode 'UTF-8',
                  $dec;

      push @{ $map{$enc} }, $dec;
   }

   for (values(%map)) {
      warn(sprintf("Ambiguous: %v04X\n", join '', @$_)) if @$_ > 1;
      $_ = $_->[0];
   }

   my $pat =
      join '|',
         map quotemeta,
            sort { length($b) <=> length($a) || $a cmp $b }
               keys %map;

   my $re = qr/$pat/;

   while (<>) {
      s/\G(?:($re)|(.))/
         if ($1) {
            $map{$1}
         } else {
            die("Unrecognized sequence starting at pos", $-[2]);
         }
      /seg;
   }
}

[download]

It also finds that you have a problem. You can't tell the difference between the following cp1252 characters after they've gone through your encoding-decoding gauntlet:

Verification: 

$ perl -MEncode -E'
   say sprintf "%v02X",
      encode "UTF-8", decode "cp1252", encode "UTF-8", chr
         for 0x00C1, 0x00CD, 0x00CF, 0x00D0, 0x00DD;
'
C3.83.EF.BF.BD
C3.83.EF.BF.BD
C3.83.EF.BF.BD
C3.83.EF.BF.BD
C3.83.EF.BF.BD

[download]

Note: I didn't have the tool check if one messed up sequence can be a substring of another messed up sequence. The sorting by descending length is there to try to handle that case if it exists. Upd: No such case exists.

In reply to Re^5: Why does Encode::Repair only correctly fix one of these two tandem characters? by ikegami
in thread Why does Encode::Repair only correctly fix one of these two tandem characters? by Jim

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.