Is this modern enough for you? ;-)

use v6;

port_check( ['perlmonks.com', 'fail.com', 'perlmonks.org'], 22 );

sub port_check( @nodes, $port ) 
{
    my @promises = @nodes.map( -> $host { 
        IO::Socket::Async.connect( $host, $port )
    });
    
    await Promise.allof( @promises );

    for @nodes Z @promises -> [$node, $promise]
    {
        if $promise.status ~~ Kept
        {
            given $promise.result
            {
                my $peer   = "{.peer-host}:{.peer-port}";
                my $socket = "{.socket-host}:{.socket-port}";
                say "$socket connected to $peer";
                .close;
            }
        }
        else
        {
            say "not connected to $node:$port";
        }
    }
}
[download]

D:\ENV>perl6 pcheck.pl
192.168.178.20:49859 connected to 216.92.34.251:22
not connected to fail.com:22
192.168.178.20:49861 connected to 209.197.123.153:22
[download]

Edit: This is the same code with a custom timeout.

use v6;

port_check( ['perlmonks.com', 'fail.com', 'fail.com', 'fail.com', 'fai
+l.com', 'fail.com', 'fail.com', 'fail.com', 'perlmonks.org'], 55, 2 )
+;

sub port_check( @nodes, $port = 22, $timeout = 10) 
{
    my @promises = @nodes.map( -> $host { 
        IO::Socket::Async.connect( $host, $port );
    });
    
    my @waits = @promises.map( -> $promise {
        Promise.anyof( Promise.in( $timeout ), $promise )
    });
    
    await Promise.allof( @waits );

    for @nodes Z @promises -> [$node, $promise]
    {
        if $promise.status ~~ Kept
        {
            given $promise.result
            {
                my $peer   = "{.peer-host}:{.peer-port}";
                my $socket = "{.socket-host}:{.socket-port}";
                say "$socket connected to $peer";
                .close;
            }
        }
        else
        {
            say "not connected to $node:$port";
        }
    }
}
[download]

---

---

Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!

Titles consisting of a single word are discouraged, and in most cases are disallowed outright.

Read Where should I post X? if you're not absolutely sure you're posting in the right place.

Please read these before you post! —

• How do I compose an effective node title?
• How do I post a question effectively?
• Markup in the Monastery

Posts may use any of the Perl Monks Approved HTML tags:

a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr

You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)

	For:		Use:
	&		&
	<		&lt;
	>		&gt;
	[		&#91;
	]		&#93;

Link using PerlMonks shortcuts! What shortcuts can I use for linking?

See Writeup Formatting Tips and other pages linked from there for more info.