Hi,

On the Mac side, I needed to install library dependencies. Thus, installed extra to cover GIF, PNG, JPEG, and TIFF at least :)

$ brew install giflib libpng libjpeg libtiff freetype

$ cpanm Imager -n
$ cpanm Imager::File::GIF -n
$ cpanm Imager::File::PNG -n
$ cpanm Imager::File::JPEG -n
$ cpanm Imager::File::TIFF -n

$ cpanm Imager::Heatmap -n
[download]

I tried your example using MCE::Map. It was cool seeing the output from 1 to 90 go by swiftly. So here it is, a parallel demonstration.

#!/usr/bin/env perl
##
# https://www.perlmonks.org/?node_id=11104262
#
# 100 simultaneous supernovae collapse into a supermassive blackhole!
# This makes a pretty picture by incrementing the sigma values on the 
# sample data resulting in an animated GIF. Please feel free to hack 
# it up and post your version!
##

use strict;
use warnings;
use Imager::Heatmap;
use MCE::Map;

my $filename = 'heatmapa.gif';
my @insert   = sample_data();
my @images   = ();
$| = 1;

print "Generating GIF frame ";

MCE::Map->init(
  max_workers => 20,
  chunk_size  => 1,
  init_relay  => ''
);

my @data = mce_map {
  my $x = $_;
  my $hmap = Imager::Heatmap->new(
    xsize  => 300,
    ysize  => 300,
    xsigma => $x,
    ysigma => $x,
  );
  $hmap->insert_datas(@insert);
  $hmap = $hmap->draw;

  my $data;
  $hmap->write(data => \$data, type => 'tiff');

  # calling relay so orderly print output
  MCE::relay { print "$x " };

  $data;

} [ 1 .. 90 ];

MCE::Map->finish;

print "done!\n";

Imager->write_multi({
  file     => $filename,
  transp   => 'none',
  gif_loop => 0,
}, map { Imager->read_multi(data => \$_) } @data);

print "Saved $filename\n";

sub sample_data {
  my @insert = ();
  while (<DATA>) {
    chomp; push @insert, [ split /\s/ ]
  }
  return @insert
}

__DATA__
...
[download]

Regards, Mario

---

---

Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!

Titles consisting of a single word are discouraged, and in most cases are disallowed outright.

Read Where should I post X? if you're not absolutely sure you're posting in the right place.

Please read these before you post! —

• How do I compose an effective node title?
• How do I post a question effectively?
• Markup in the Monastery

Posts may use any of the Perl Monks Approved HTML tags:

a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr

You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)

	For:		Use:
	&		&
	<		&lt;
	>		&gt;
	[		&#91;
	]		&#93;

Link using PerlMonks shortcuts! What shortcuts can I use for linking?

See Writeup Formatting Tips and other pages linked from there for more info.