It does work, it's just that you don't understand what it's comparing and why they look different to uniq. Each element in your @test_data is a separate hashref which will compare differently with another hashref which might have identical contents.

For this particular usage with this (relatively small) amount of data you might could kludge something up by serializing items and then checking the serialized version.

Update: Ooops, forgot to enable sorting of keys with canonical(1). Updated output as well. I did say it was a kludge . . . 

use 5.018;
use Data::Dumper;
use JSON::XS;

my @test_data = (
    { Tag1 => "1", Tag2 => "a" },
    { Tag1 => "1", Tag2 => "a" },
    { Tag1 => "1", Tag2 => "b" },
    { Tag1 => "1", Tag2 => "c" },
    { Tag1 => "1", Tag2 => "a" },
    { Tag1 => "2", Tag2 => "a" },
    { Tag1 => "2", Tag2 => "d" },
    { Tag1 => "2", Tag2 => "a" },
    { Tag1 => "3"},
    { Tag1 => "sun", Tag2 => "a" },
    { Tag1 => "sun", Tag2 => "a" },
);

## showing the hashrefs are different regardless of contents
say qq{idx: $_\tref: $test_data[$_]} for 0..2;

my $j = JSON::XS->new->pretty(0)->ascii(1)->canonical(1);

my %seen_items;
my @unique;
for my $item ( @test_data ) {
  my $ser = $j->encode( $item );
  push @unique, $item unless $seen_items{ $ser }++;
}

print Dumper \@unique;
__END__
idx: 0    ref: HASH(0x7fb3ac003ee8)
idx: 1    ref: HASH(0x7fb3ac015cf8)
idx: 2    ref: HASH(0x7fb3ac015dd0)
$VAR1 = [
          {
            'Tag1' => '1',
            'Tag2' => 'a'
          },
          {
            'Tag2' => 'b',
            'Tag1' => '1'
          },
          {
            'Tag1' => '1',
            'Tag2' => 'c'
          },
          {
            'Tag1' => '2',
            'Tag2' => 'a'
          },
          {
            'Tag1' => '2',
            'Tag2' => 'd'
          },
          {
            'Tag1' => '3'
          },
          {
            'Tag1' => 'sun',
            'Tag2' => 'a'
          }
        ];

[download]

The cake is a lie.
The cake is a lie.
The cake is a lie.

In reply to Re: Eliminate exact duplicates from array of hashes by Fletch
in thread Eliminate exact duplicates from array of hashes by Anonymous Monk

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.