I created a Makefile like this:

SHELL = /bin/bash

.PHONY: data
data:
    for i in {1..10} ; do for j in {1..10} ; do echo "[$$i,$$j,$$RANDO
+M]" > $$i-$$j.json ; done ; done

.PHONY: simulate_cron
simulate_cron: data
    while : ; do \
        i=$$((1 + RANDOM % 10)) ; j=$$((1 + RANDOM % 10)) ; echo "[$$i
+,$$j,$$RANDOM]" > tmp ; mv tmp $$i-$$j.json ;\
    done

.PHONY: query
query:
    time perl query.pl

.PHONY: clean
clean:
    rm -f *.json
[download]

Now, you can run

make simulate_cron
[download]

Then, run

make query
[download]

#!/usr/bin/perl
use warnings;
use strict;
use feature qw{ say };

use Cpanel::JSON::XS qw{ decode_json };

my %cache;
for (1 .. 1000) {
    my @queries = map [ map int 1 + rand 10, 1, 2 ], 1 .. 50;
    for my $query (@queries) {
        my ($x, $y) = @$query;

        # delete $cache{$x}{$y};  # <- Uncomment to simulate no cache.

        my $value;
        if (exists $cache{$x}{$y}
            && (stat "$x-$y.json")[9] == $cache{$x}{$y}{last}
        ) {
            $value = $cache{$x}{$y}{value};

        } else {
            open my $in, '<', "$x-$y.json" or die $!;
            $cache{$x}{$y}{last} = (stat $in)[9];
            $value = $cache{$x}{$y}{value} = decode_json(do { local $/
+; <$in> })->[2];
        }
        say "$x, $y: $value";
    }
}
[download]

With the delete line uncommented, it takes about 0.400s to terminate. With the line commented, it runs under 0.100s, i.e. slightly more than 4 times faster.

Notes:

1. The simulation uses mv to create the JSON files so they change is atomic. If we wrote to the file directly instead, we could get occasional errors when reading it.
2. We store the modification time before we read the value. There's a race condition: the value may change after we retrieved the modification time, but before we read the value. But it doesn't break the code: we return the correct value, but we might read it from the file once more next time.
3. I guess the cron process doesn't change all the files all the time, so the real benefit of this kind of cache might be much lesser in your real environment.