I'd probably use HTML::TableExtract or a real parser (XML::LibXML can parse HTML, too). But for that, I'd need the real HTML table, the one you posted is kind of quoted (note all the backslashes before double quotes). How was the table obtained? Can't you obtain the real HTML? As a poor man's solution, you can just replace each \" with a plain ". 
#!/usr/bin/perl
use warnings;
use strict;
use feature qw{ say };

use HTML::TableExtract;

my $te = 'HTML::TableExtract'->new;
$te->parse(do { local $/; <> =~ s/\\"/"/gr });
for my $table ($te->tables) {
    for my $row ($table->rows) {
        chomp @$row;
        say "@$row[0, 1]";
    }
}

[download]
Output: 
Envvironment Last Updated
bus00eqa 25-Apr-2020
bus00eqz 29-Feb-2020
den00pyy 25-Apr-2020

[download]

Or, similarly: 

#!/usr/bin/perl
use warnings;
use strict;
use feature qw{ say };

use XML::LibXML;

my $dom = 'XML::LibXML'->load_html(
    string => do { local $/; <> =~ s/\\"/"/gr });

for my $row ($dom->findnodes('//table/tbody/tr')) {
    my @cells = $row->findnodes('td | th');
    say join ' ', map $_->textContent, @cells[0, 1];
}

[download]

map{substr$_->[0],$_->[1]||0,1}[\*||{},3],[[]],[ref qr-1,-,-1],[{}],[sub{}^*ARGV,3]

In reply to Re: Update html table rows with new values at runtime by choroba
in thread Update html table rows with new values at runtime by saro

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.