Please see Building Regex Alternations Dynamically.

use warnings;
use strict;
use Text::CSV;

my %terms;

my $csv = Text::CSV->new({ binary=>1, auto_diag=>2, sep_char=>"|" });
my $fh = *DATA; # normally you'd open() a file here
while ( my $row = $csv->getline($fh) ) {
    my $id = shift @$row;
    @terms{@$row} = ($id) x @$row;
}
$csv->eof or $csv->error_diag;

my ($regex) = map {qr/$_/} join '|', map {quotemeta}
    sort { length $b <=> length $a or $a cmp $b } keys %terms;

my $input = q{2020 Ford F 250 is great but I prefer Tesla Model-V};

(my $output = $input) =~ s/($regex)/<$terms{$1}><$1>/g;

use Test::More tests=>1;
is $output,
    q{<2><2020 Ford F 250> is great but I prefer <1><Tesla Model-V>};

__DATA__
1|Tesla S|Tesla model V|Tesla model|Tesla|Tesla Model-V
2|Ford RAM truck|2020 Ford Mustand|Ford ranger|Ranger|ford|2020 Ford F
+-250|2020 Ford F 250|Ford F 250
3|GM Chevrolet|GM Chevy|GM Chevrolet 2020|Chevrolet|Chevy|Chevrolet 20
+20|GM Chevrolet volt|Chevrolet Captiva Sport|General motors|GM

[download]

In reply to Re: Matching terms in text by haukex
in thread Matching terms in text by rajaman

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.