I've been doing a lot of work with Mojolicious lately and I've been liking it. It provides Mojo::IOLoop::Subprocess to fork off a subprocess so that one doesn't block the server.

#!/usr/bin/env perl
use Mojolicious::Lite -signatures;
use Mojo::IOLoop;

get '/' => sub ($c) {
    $c->render(template => 'index');
} => 'index';

post '/doit' => sub ($c) {
    $c->render_later;
    Mojo::IOLoop->subprocess->run_p(sub {
        # this code is actually running in a subprocess!
        sleep 10;
        return "I did the thing!";
    })->then(sub (@results) {
        $c->render(text => "@results");
    })->catch(sub ($err) {
        $c->reply->exception($err);
    });
} => 'doit';

app->start;

__DATA__

@@ index.html.ep
% layout 'main', title => 'Hello, World!';
<div>
%= form_for doit => ( method=>'post' ) => begin
%= submit_button 'Do the thing'
%= end
</div>

@@ layouts/main.html.ep
<!DOCTYPE html>
<html>
<head><title><%= title %></title></head>
<body>
%= content
</body>
</html>

[download]

You could combine this with e.g. aychnronous AJAX form submission like I showed here, or one could probably even send progress messages (a feature provided by Mojo::IOLoop::Subprocess) to the browser using something like Javascript's EventSource API, which I included an example of here.

Update 2022-04-07: I've now posted an example of just that here.

In reply to Re: Recommend an asynchronous HTTP server CPAN modules? (updated) by haukex
in thread Recommend an asynchronous HTTP server CPAN modules? by sectokia

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.