I slurp the data into a string then use regexen and @- & @+ to find the point just after the start marker and just before the end marker. I then use substr and join to replace the necessary text between the markers, working backwards from the right side of the string by sorting start marker position into descending order, greping away any incomplete marker events. ( Note that I have formed the habit of opening file handles against HEREDOCs rather than using the __DATA__ section as it allows me to use multiple data sources in scripts as necessary. )

use strict;
use warnings;

open my $inFH, q{<}, \ <<__EOD__ or die qq{open: < HEREDOC:$!\n};
aaa
AAAAAA
ccc
ddd
BBBBBB
EEEEEE
zzz
xxx
yyy
FFFFFF
111
GGGGGG
222
333
CCCCCC
444
555
666
DDDDDD
777
888
999
__EOD__

my $inText = do {
   local $/;
   <$inFH>;
   };

close $inFH or die qq{close: < HEREDOC:$!\n};

my @events = (
   {  
       start => qr{(?x) GGGGGG $/ },
       stop  => qr{(?x) HHHHHH $/ },
       repl  => [ qw{ f31 f32 f33 f34 } ],
   },
   {
       start => qr{(?x) AAAAAA $/ },
       stop  => qr{(?x) BBBBBB $/ },
       repl  => [ qw{ f11 f12 f13 } ],
   },
   {  
       start => qr{(?x) EEEEEE $/ },
       stop  => qr{(?x) FFFFFF $/ },
       repl  => [ qw{ f31 f32 f33 f34 } ],
   },
   {  
       start => qr{(?x) CCCCCC $/ },
       stop  => qr{(?x) DDDDDD $/ },
       repl  => [ qw{ f21 f22 } ],
   },
   );

foreach my $rhEvent ( @events )
{
    $rhEvent->{ startPos } =
       $inText =~ $rhEvent->{ start }
       ? $+[ 0 ]
       : -1;
    $rhEvent->{ stopPos }  = 
       $inText =~ $rhEvent->{ stop }
       ? $-[ 0 ]
       : -1;
}

substr
   $inText,
   $_->{ startPos },
   $_->{ stopPos } - $_->{ startPos },
   join $/, q{}, @{ $_->{ repl } }, q{}
   for
      sort { $b->{ startPos } <=> $a->{ startPos } }
      grep { $_->{ startPos } >= 0 && $_->{ stopPos } >= 0 }
      @events;

print $inText;

[download]

The output.

aaa
AAAAAA
f11
f12
f13
BBBBBB
EEEEEE
f31
f32
f33
f34
FFFFFF
111
GGGGGG
222
333
CCCCCC
f21
f22
DDDDDD
777
888
999

[download]

I hope this is of interest.

Update: Corrected grep link.

Cheers,

JohnGG

In reply to Re: The best way to replace several fragments of the file starting with the one pattern(marker) and ending with another pattern/marker. by johngg
in thread The best way to replace several fragments of the file starting with the one pattern(marker) and ending with another pattern/marker. by likbez

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.