Both perlver (from Perl::MinimumVersion) and perlver-fast (from Perl::MinimumVersion::Fast, which is much faster, but requires perl-5.8.0 and up) are extremely useful, but both lack some covarage, and I personally miss support for -e.

Another problem is that both only report a single issue:

$ cat test.pl
#!/usr/bin/perl

use strict;
use warnings;                   # Requires 5.6.0

my $a = 5;

-e -f -s $0 and print "0\n";    # Requires 5.8.0
1 < $a < 10 and print "1\n";    # Requires 5.31.11 / 5.32.0
$a //= 42;                      # Requires 5.10.0
$a =~ s{0\K}{};                 # Requires 5.10.0
$b = $a =~ s{0}{1}r;            # Requires 5.14.0

$ perlver --blame test.pl

 ------------------------------------------------------------
 File    : test.pl
 Line    : 12
 Char    : 12
 Rule    : _regex
 Version : 5.013002
 ------------------------------------------------------------
 s{0}{1}r
 ------------------------------------------------------------
[download]

perlver-fast does not support --blame :(

$ perlver-fast test.pl
test.pl: 5.010
[download]

If you replace the script of perlver-fast with this code:

#!/usr/bin/env perl
use strict;
use warnings;
use Getopt::Long qw(:config bundling passthrough);
use Perl::MinimumVersion::Fast;

GetOptions (
    "e:s" => \my $expr,
    "v"   => \my $verbose,
    ) or die;

if (@ARGV) {
    report ($_, $_) for @ARGV;
    }
elsif ($expr) {
    report ("-e", \$expr);
    }
else {
    my $src = do { local $/; <> };
    report ("STDIN", \$src);
    }

sub report {
    my ($in, $src) = @_;
    my $v = Perl::MinimumVersion::Fast->new ($src);
    printf "%s: %s / %s\n", $in, $v->minimum_version, $v->minimum_synt
+ax_version;
    $verbose or return;
    my @markers = $v->version_markers;
    while (@markers) {
        my ($pv, $m) = splice @markers, 0, 2;
        printf "%-10s %s\n", $pv, $_ for @$m;
        }
    }
[download]

You have support for -e:

$ perlver-fast -e '$a //= 4'
-e: 5.010 / 5.010
[download]

where it would otherwise fail with Unknown file: -e at ...

With this modified version you can also show the reasons (with -v)

$ perlver-fast -ve '$a //= 4; package foo 0.04 { 1; }'
-e: 5.014 / 5.014
5.010      //= operator
5.012      package NAME VERSION
5.014      package NAME VERSION BLOCK
[download]

It however does not (yet) detect \K or s{}{}r (issues are created)

$ perlver-fast -ve '$a = "fo" =~ s{f\K}{o}r'
-e: 5.006 / 5.006
[download]

---

---

Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!

Titles consisting of a single word are discouraged, and in most cases are disallowed outright.

Read Where should I post X? if you're not absolutely sure you're posting in the right place.

Please read these before you post! —

• How do I compose an effective node title?
• How do I post a question effectively?
• Markup in the Monastery

Posts may use any of the Perl Monks Approved HTML tags:

a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr

You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)

	For:		Use:
	&		&
	<		&lt;
	>		&gt;
	[		&#91;
	]		&#93;

Link using PerlMonks shortcuts! What shortcuts can I use for linking?

See Writeup Formatting Tips and other pages linked from there for more info.