Your program would be much simpler if you reversed the order of your subscripts. Each column of your data is a set of data. It is convenient to have each set stored as its own array. 
use strict;
use warnings;
use List::Util qw(sum);
my @raw;
my $n;

while (my $line = <DATA>) {
    my @cols = split / /, $line;
    foreach my $j (0..$#cols) {
        push @{$raw[$j]}, $cols[$j];
    }
}

{
    local $, = ' ';
    print process_column($_), "\n" foreach @raw;
}



sub process_column {
    my @x = @{$_[0]};
    my $n = @x;
    my $x_tot = sum( @x );
    my @x_jack = map { ($x_tot - $_) / ($n - 1) } @x;
    my $g_jack_av;
    my $g_jack_err;
    #foreach my $dg (@x) {
    foreach my $dg (@x_jack) {   #UPDATE
        $g_jack_av += $dg;
        $g_jack_err += $dg**2;
    }
    $g_jack_av  /= $n;
    $g_jack_err /= $n;
    $g_jack_err = sqrt(($n-1)*abs($g_jack_err-$g_jack_av**2));
    return ($g_jack_av, $g_jack_err);
}


__DATA__
1.1 2.1 3.1 4.1
1.2 2.2 3.2 4.2
1.3 2.3 3.3 4.3
1.4 2.4 3.4 4.4

[download]

OUTPUT

1.25 0.193649167310372
2.25 0.193649167310365
3.25 0.193649167310338
4.25 0.193649167310365

[download]

OUTPUT (with correction)

1.25 0.064549722436785
2.25 0.0645497224367747
3.25 0.0645497224367334
4.25 0.064549722436816

[download]

UPDATE: Corrected error reported by AnomalousMonk in Re^2: Calculate jackknife error from of each column of a multi-column file

Bill

In reply to Re: Calculate jackknife error from of each column of a multi-column file by BillKSmith
in thread Calculate jackknife error from of each column of a multi-column file by pyari_billi

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.