G'day Karl,

As we're all making guesses, here's mine: 

use strict;
use warnings;

use constant {
    SEP => $;,
    TRY => 5, # arbitrary
};

use Data::Dump;
use List::Util "shuffle";

my @AoAs = (
    [ [ 2, 3, 4, 5 ], [ 2, 3, 4, 5 ], [ 2, 3, 4, 5 ], ],
    [ [ 3, 2, 4, 5 ], [ 4, 3, 2, 5 ], [ 2, 5, 4, 3 ], ],
);

for (@AoAs) {
    dd $_;
    randomise($_);
}

sub randomise {
    my ($AoA) = @_;

    my %seen;
    @seen{map mk_key(@$_), @$AoA} = (1) x @$AoA;

    for my $i (0 .. $#$AoA) {
        my $tries = 0;

        while (1) {
            my @shuffled = shuffle @{$AoA->[$i]};

            if ($seen{mk_key(@shuffled)}++) {
                die "Too many tries" if ++$tries >= TRY;
            }
            else {
                $AoA->[$i] = [@shuffled];
                last;
            }
        }
    }

    dd $AoA;
}

sub mk_key {
    join SEP, @_;
}

[download]

Output from two example runs:

[[2 .. 5], [2 .. 5], [2 .. 5]]
[[2, 4, 3, 5], [2, 3, 5, 4], [2, 5, 3, 4]]
[[3, 2, 4, 5], [4, 3, 2, 5], [2, 5, 4, 3]]
[[5, 4, 3, 2], [4, 5, 2, 3], [5, 2, 3, 4]]

[download]
[[2 .. 5], [2 .. 5], [2 .. 5]]
[[4, 5, 2, 3], [3, 5, 2, 4], [2, 5, 4, 3]]
[[3, 2, 4, 5], [4, 3, 2, 5], [2, 5, 4, 3]]
[[5, 4, 3, 2], [3, 4, 5, 2], [2, 5, 3, 4]]

[download]

— Ken

In reply to Re: How to shuffle this AoA by kcott
in thread How to shuffle this AoA by karlgoethebier

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.