Your line for my $key1 (keys %rankBased) { implies that you have an HoHoH structure to start with and, as others have mentioned, you can't have "ordered" hashes without a bit of jiggery-pokery. To retain a sorted order you need to introduce an array in there somewhere. The following code constructs an HoAoHoH structure, inserting an array between your $key1 and $key2 so that the sort is preserved.

use strict;
use warnings;

use Data::Dumper;

my %rankBased = (
   q{191} => {
      test1 => { score => 9.18 },
      test2 => { score => 2.84 },
      test3 => { score => 15.62 },
      test4 => { score => 11.84 },
      },
   q{190} => {
      test1 => { score => 13.28 },
      test2 => { score => -47.56 },
      test3 => { score => 18.50 },
      test4 => { score => 14.88 },
      },
   );

my %sortedByRank;
foreach my $key ( keys %rankBased )
{
    $sortedByRank{ $key } = [
       map  { { $_ => { score => $rankBased{ $key }->{ $_ }->{ score }
+ } } }
       sort {
          $rankBased{ $key }->{ $b }->{ score }
          <=>
          $rankBased{ $key }->{ $a }->{ score }
          } keys %{ $rankBased{ $key } }
       ];
}

print Data::Dumper->Dumpxs( [ \ %sortedByRank ], [ qw{ *sortedByRank }
+ ] );
[download]

The Data::Dumper output.

%sortedByRank = (
                  '191' => [
                             {
                               'test3' => {
                                            'score' => '15.62'
                                          }
                             },
                             {
                               'test4' => {
                                            'score' => '11.84'
                                          }
                             },
                             {
                               'test1' => {
                                            'score' => '9.18'
                                          }
                             },
                             {
                               'test2' => {
                                            'score' => '2.84'
                                          }
                             }
                           ],
                  '190' => [
                             {
                               'test3' => {
                                            'score' => '18.5'
                                          }
                             },
                             {
                               'test4' => {
                                            'score' => '14.88'
                                          }
                             },
                             {
                               'test1' => {
                                            'score' => '13.28'
                                          }
                             },
                             {
                               'test2' => {
                                            'score' => '-47.56'
                                          }
                             }
                           ]
                );
[download]

I hope this guess at your data and intentions is helpful.

Update: Changing the map line to

       map  { { $_ => { %{ $rankBased{ $key }->{ $_ } } } } }
[download]

will work if the innermost hashes have multiple key/value pairs.

---

---

Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!

Titles consisting of a single word are discouraged, and in most cases are disallowed outright.

Read Where should I post X? if you're not absolutely sure you're posting in the right place.

Please read these before you post! —

• How do I compose an effective node title?
• How do I post a question effectively?
• Markup in the Monastery

Posts may use any of the Perl Monks Approved HTML tags:

a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr

You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)

	For:		Use:
	&		&
	<		&lt;
	>		&gt;
	[		&#91;
	]		&#93;

Link using PerlMonks shortcuts! What shortcuts can I use for linking?

See Writeup Formatting Tips and other pages linked from there for more info.