I am using dbix::dump data from database Which is in utf-8. ... Is there any way i can dump data in proper format.

DBIx::Dump appears to pre-date most of the unicode support in Perl. I would avoid it for such tasks. Here is an SSCCE which avoids it. Feel free to tweak for your own database engine.

use strict;
use warnings;

use DBI;
use Encode qw/find_encoding/;
use Text::CSV qw/csv/;
use Test::More tests => 2;

my $enc = find_encoding ("UTF-8") or die 'Cannot set encoding';
my $str = "\N{ETHIOPIC SYLLABLE QAA}";

my $dbh = DBI->connect ("dbi:mysql:test", 'nobody') or die "No db";
$dbh->do ('DROP TABLE IF EXISTS stuff');
$dbh->do ('CREATE TABLE stuff ( yada varchar(255) charset utf8 );');
$dbh->do ('INSERT INTO stuff VALUES (?)', undef, $enc->encode ($str));

# Read it back from the DB
my @fromdb;
my $sth = $dbh->prepare ('SELECT yada FROM stuff');
$sth->execute;
while (my $r = $sth->fetchrow_arrayref) {
    $_ = $enc->decode ($_) for @$r;
    push @fromdb, $r;
}
is $fromdb[0]->[0], $str, 'Back from DB';

# Write it out to a file
csv (in => \@fromdb,
    out => 'outfoo.csv',
    encoding => 'utf-8'
);

# Check the contents of the file
my $fromfile = csv (in => 'outfoo.csv', encoding => 'utf-8');
is $fromfile->[0][0], $str, 'Back from file';

[download]

🦛

In reply to Re: Dump data from unicode database by hippo
in thread Dump data from unicode database by sachin raj aryan

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.