Anonmonk, here is how but I can't see how this is related to Inline::C.

Case2 (pass a scalar - not a ref) is obviously failing. But I don't think that should apply to Inline::C because AFAICT a scalar, like a scalarref and any ref, is passed as an SV * which I can affect its PV field within func() and insert an arrayref in there. A good warmup though thanks.

use strict;
use warnings;

use Test::More;

use Data::Dumper;

my $correct_result = make_a_rowsxcols_array(5,3);
print Dumper($correct_result);

### $#out = -1; # clears an array;

# Case1: pass it an arrayref
my $T = 'Case1';
my @out = (1,2,3);
is( case1(\@out), 0, "$T: returned success.");
is_deeply(\@out, $correct_result, "$T: correct result.");

# Case2: pass it a scalar
$T = 'Case2';
my $x = 123;
is( case2($x), 0, "$T: returned success.");
is_deeply($x, $correct_result, "$T: correct result.");

# Case3: pass it a scalarref
$T = 'Case3';
my $y = 123;
is( case3(\$y), 0, "$T: returned success.");
is_deeply($y, $correct_result, "$T: correct result.");

done_testing();

sub case1 {
    # pass an arrayref, clear it and make it 5rowsx3cols
    my $out = $_[0];
    return 1 unless ref($out) eq 'ARRAY';
    $#{ $out } = -1;
    push @$out, @{ make_a_rowsxcols_array(5,3) };
    return 0;
}

sub case2 {
    # pass a simple scalar, make it an arrayref
    my $out = $_[0];
    return 1 unless ref($out) eq '';

    $out = make_a_rowsxcols_array(5,3);
    return 0;
}

sub case3 {
    # pass a scalarref, fill it with an arrayref to 5rowsx3cols
    my $out = $_[0];
    return 1 unless ref($out) eq 'SCALAR';

    undef $$out;
    $$out = make_a_rowsxcols_array(5,3);
    return 0;
}


sub make_a_rowsxcols_array {
    [ map { [ (42)x$_[1] ] } 1..$_[0] ]
}

[download]

bw, bliako

In reply to Re^2: Inline::C : passing parameters to functions, modifying by reference by bliako
in thread Inline::C : passing parameters to functions, modifying by reference by bliako

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.