You already answered your own question by following up to state that -exitval => 'NOEXIT' works. I had found this to work just fine, as well. But it wouldn't be Perl if it didn't arouse curiosity. I was curious if I could override CORE::GLOBAL::exit effectively. Turns out I can (though this isn't to say I should):

#!/usr/bin/env perl

use strict;
use warnings;

our $override_exit = 0;
BEGIN {
    no warnings 'redefine';
    *CORE::GLOBAL::exit = sub :prototype(;$) {
        if ($override_exit) {
            warn "EXIT_OVERRIDE\n";
        }
        else {
            CORE::exit($_[0] // 0);
        }
    };
}

use Pod::Usage;

{
    local $override_exit = 1;

    print "Calling pod2usage(1)\n";
    pod2usage(1);
    print "We are still here after overriding exit.\n";
}

print "calling pod2usage with -exitval => 'NOEXIT'\n";
pod2usage(-exitval => 'NOEXIT');
print "We are still here after using -exitval => 'NOEXIT'.\n";
[download]

This produces the following output:

Calling pod2usage(1)
EXIT_OVERRIDE
We are still here after overriding exit.
calling pod2usage with -exitval => 'NOEXIT'
We are still here after using -exitval => 'NOEXIT'.
[download]

So this demonstrates that NOEXIT works, and that overriding CORE::GLOBAL::exit can work.

---

---

Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!

Titles consisting of a single word are discouraged, and in most cases are disallowed outright.

Read Where should I post X? if you're not absolutely sure you're posting in the right place.

Please read these before you post! —

• How do I compose an effective node title?
• How do I post a question effectively?
• Markup in the Monastery

Posts may use any of the Perl Monks Approved HTML tags:

a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr

You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)

	For:		Use:
	&		&
	<		&lt;
	>		&gt;
	[		&#91;
	]		&#93;

Link using PerlMonks shortcuts! What shortcuts can I use for linking?

See Writeup Formatting Tips and other pages linked from there for more info.