Just for fun, here's a few different ways to do compression. Note that I assume you have a longer file with many lines that are 63 chars each. I remove the newlines (they can always be replaced later) because some compression algorithms can do better with longer strings of data, and the newline introduces a fourth character to the mix.

Have fun ! 

#!/usr/bin/perl

use strict; # https://perlmonks.org/?node_id=11136582
use warnings;

for my $try (
  [ 'gzip/gunzip', \&compgzip, \&uncompgzip ],
  [ '2 bit code, 6 bit runlength', \&comp62, \&uncomp62 ],
  [ '2 bits per letter', \&comp2bits, \&uncomp2bits ],
  [ 'groups of 5,2,1', \&comp5, \&uncomp5 ],
  )
  {
  my ($method, $comp, $uncomp) = @$try;
  print "\n------------------------------ Compression by $method\n\n";
  my $data = <<END;
ABBCBCAAAAABBCBCACCCAAAAACAAAAABBBBBAAAAABBAAAAAAAABBCCCACCAABC
BCCCBCAACAABBBCAAACCAAAAACAAAAABBBBBAAAAABBAAAAAAAABBCCCACCABBC
ABCCBBBAAAABBABCACABCCCCCCAAAAABBCBBCCCCAAAAAAAAAAAAACCCACCACCC
END

  $data =~ tr/\n//d; # remove \n they can be re-inserted later
  print "length of            data @{[ $data =~ tr/ABC// ]}\n";
  my $compressed = $comp->($data);
  print "length of compressed data @{[ length $compressed ]}\n";
  #use Data::Dump 'dd'; dd $compressed;
# print unpack('H*', $compressed), "\n";
  my $uncompressed = $uncomp->($compressed);
  printf "compressed to %.1f%%\n",
    100 * length($compressed) / length $uncompressed;
  print $data eq $uncompressed ? "MATCH" : "************ no MATCH", "\
+n";
  }

# compress by groups of 5,2,1 to single letter

sub comp5
  {
  my @code = map glob('{A,B,C}' x $_), 5, 2, 1;
  my %code;
  @code{@code} = map chr, 1 .. @code;
  local $" = '|';
  shift =~ s/(@code)/$code{$1}/gr
  }
sub uncomp5
  {
  my @code = map glob('{A,B,C}' x $_), 5, 2, 1;
  my %code;
  @code{map chr, 1 .. @code} = @code;
  join '', @code{split //, shift};
  }

# compress by lower two bits of letter

sub comp2bits
  {
  my ($ans, $n) = ('', 0);
  vec($ans, $n++, 2) = 3 & ord $_ for split //, shift;
  $ans;
  }
sub uncomp2bits
  {
  my $comp = shift;
  join '', map
    {
    ('', 'A', 'B', 'C')[ vec $comp, $_, 2]
    } 0 .. -1 + 4 * length $comp;
  }

# compress by runlength or 6 bits length and 2 bits letter code

sub comp62
  {
  shift =~ s/([ABC])\1{0,62}/ chr( length($&) << 2 | ord($1) & 3) /ger
+;
  }
sub uncomp62
  {
  shift =~ s/./ (($& & "\3") | '@') x (ord($&) >> 2) /gesr;
  }

# compress by gzip

use IO::Compress::Gzip qw(gzip);
sub compgzip
  {
  gzip \(shift) => \(my $output);
  $output;
  }
use IO::Uncompress::Gunzip qw(gunzip);
sub uncompgzip
  {
  gunzip \(shift) => \(my $output);
  $output;
  }

[download]

Outputs: 

------------------------------ Compression by gzip/gunzip

length of            data 189
length of compressed data 77
compressed to 40.7%
MATCH

------------------------------ Compression by 2 bit code, 6 bit runlen
+gth

length of            data 189
length of compressed data 76
compressed to 40.2%
MATCH

------------------------------ Compression by 2 bits per letter

length of            data 189
length of compressed data 48
compressed to 25.4%
MATCH

------------------------------ Compression by groups of 5,2,1

length of            data 189
length of compressed data 39
compressed to 20.6%
MATCH

[download]

I tried gzip on the groups 5,2,1 compression string and gzip made it longer :)

In reply to Re: How to efficently pack a string of 63 characters by tybalt89
in thread How to efficently pack a string of 63 characters by baxy77bax

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.