While the hash is string-interpolated, is the hash-key inside an executed expression!

And ${test}_bar is not a valid expression.

Debugger demo: 

  DB<28> sub EXPR { print "executed" }

  DB<29> "  $hash{ EXPR() }  "
executed

  DB<30> ${test}_bar
Bareword found where operator expected at ...

[download]

So multiple ways to do it are:

use strict;
use warnings;

my %test_hash = ("foo_bar" => "baz");
my $test = "foo";
my $key = "${test}_bar";

my $var1 = "aaa/$test_hash{$key}";
print("var1 = $var1\n");


my $var2 = "aaa/$test_hash{ $test . '_bar' }";    # concat operator
print("var2 = $var2\n");


my $var3 = "aaa/$test_hash{ qq(${test}_bar) }";   # qq() inside ""
print("var3 = $var3\n");


my $var4 = qq(aaa/$test_hash{ "${test}_bar" });   # "" inside qq()
print("var4 = $var4\n");

[download]

var1 = aaa/baz
var2 = aaa/baz
var3 = aaa/baz
var4 = aaa/baz

[download]

And since you introduced printf

my $var5 = sprintf 'aaa/%s', $test_hash{ "${test}_bar" };   # inside-o
+ut
print("var5 = $var5\n");

[download]

update

On a side note: Another good reason why perl-strings and here-docs are not a safe template syntax.

Cheers Rolf
(addicted to the Perl Programming Language :)
Wikisyntax for the Monastery

In reply to Re: curly braces inside of curly braces by LanX
in thread curly braces inside of curly braces by Special_K

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.