Have you seen formline, maybe that could help you? I think it has several limitations, like not handling pagination IIRC, but it can be used as a kind of printf for formats, so both formats and their inputs can be managed as regular strings, which sounds like it might be an advantage in your situation; I'm not sure if that would outweigh the limitations in your case though. Anyway, an example is given in perlform, here's an example based on that:

#!/usr/bin/env perl
use warnings;
use strict;

print "--- normal format: ---\n";

my ($foo, $bar, $quz);
format STDOUT = 
| @|||| | @###.## | ^>>>>>> |
$foo,     $bar,     $quz
.

$quz = "a b c d e f g h i j k";
for my $x (["foo",12.3],["bar",3.3333],["quz",1000.009]) {
    ($foo, $bar) = @$x;
    write;
}

print "--- swrite: ---\n";

sub swrite {
    my $fmt = shift;
    local $^A = "";
    formline $fmt, @_;
    return $^A;
}

my $myformat = <<'_X_';
| @|||| | @###.## | ^>>>>>> |
_X_

my $quz2 = "a b c d e f g h i j k";
for my $x (["foo",12.3],["bar",3.3333],["quz",1000.009]) {
    print swrite($myformat, @$x, $quz2);
}

__END__
# Output:

--- normal format: ---
|  foo  |   12.30 | a b c d |
|  bar  |    3.33 | e f g h |
|  quz  | 1000.01 |   i j k |
--- swrite: ---
|  foo  |   12.30 | a b c d |
|  bar  |    3.33 | e f g h |
|  quz  | 1000.01 |   i j k |

[download]

In reply to Re: caching formats by Anonymous Monk
in thread caching formats by hotpelmen

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.