Using XML::LibXML and Template: 
#!/usr/bin/perl
use warnings;
use strict;

use XML::LibXML;
use Template;

my $xpc = 'XML::LibXML::XPathContext'->new;
$xpc->registerNs(a => 'http://www.w3.org/2005/Atom');
$xpc->registerNs(y => 'http://www.youtube.com/xml/schemas/2015');
$xpc->registerNs(m => 'http://search.yahoo.com/mrss/');

my $dom = 'XML::LibXML'->load_xml(location => 'videos.xml');

my $title = $xpc->findvalue('/a:feed/a:title', $dom);
my $name  = $xpc->findvalue('/a:feed/a:author/a:name', $dom);

my $entries;
for my $entry ($xpc->findnodes('/a:feed/a:entry', $dom)) {
    my $title       = $xpc->findvalue('a:title', $entry);
    my $url         = $xpc->findvalue('a:link/@href', $entry);
    my $description = $xpc->findvalue('m:group/m:description', $entry)
+;
    push @$entries, {url         => $url,
                     title       => $title,
                     description => $description || '--'};
}

binmode *DATA, ':encoding(UTF-8)';
my $template = do { local $/; <DATA> };
my $tt = 'Template'->new;
binmode *STDOUT,  ':encoding(UTF-8)';
$tt->process(\$template, {title   => $title,
                          name    => $name,
                          entries => $entries});

__DATA__
<h3>[% title %]</h3>

<b>[% name %]</b>

<ul>
[% FOR entry IN entries %]
<li> [[% entry.url %]|[% entry.title | html %]]
<p><i>[% entry.description | html %]
</i></p></li>
[% END %]
</ul>

[download]

map{substr$_->[0],$_->[1]||0,1}[\*||{},3],[[]],[ref qr-1,-,-1],[{}],[sub{}^*ARGV,3]

In reply to Re: Challenge: Parse XML Feed for Youtube channel -- XML::LibXML + Template by choroba
in thread Challenge: Parse XML Feed for Youtube channel by LanX

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.