This is one way to do it without a hash table. Your grouping constraints can be enforced by sorting the table. then roll through the table doing sums and printing every time the grouping changes.

use strict;
use warnings;
use Data::Dump qw(pp);

use constant { "AcctName" => 0, "EntityName" => 1, "UnitName" => 2};

my @array = (
             ['Account01',    'Entity01',    'Unit01',    1,    2,    
+3],
             ['Account01',    'Entity01',    'Unit01',    4,    5,    
+6],
             ['Account02',    'Entity02',    'Unit02',    10,    11,  
+  12],
             ['Account01',    'Entity01',    'Unit01',    7,    8,    
+9] );

@array = sort {$a->[AcctName] cmp $b->[AcctName]
                              or
               $a->[EntityName] cmp $b->[EntityName]
                                or
               $a->[UnitName] cmp $b->[UnitName] }@array;
pp \@array;   

die "input array too small!!" unless @array>=2;
my $firstRowRef = shift @array;
my @startRow = @$firstRowRef;

foreach my $row_ref (@array)
{
    my @curRow = @$row_ref;
    
    if ($curRow[0] ne $startRow[0] or
        $curRow[1] ne $startRow[1] or
        $curRow[2] ne $startRow[2] )
    {
        print "@startRow\n";  # new grouping
        @startRow = @curRow;
    }
    else                      # group continuation
    {                         # add current month #'s to totals
        $startRow[3]+=$curRow[3];
        $startRow[4]+=$curRow[4];
        $startRow[5]+=$curRow[5];
    }    
}

print "@startRow\n";  # This is for the last row of array           
               
__END__
sorted array is:
[
  ["Account01", "Entity01", "Unit01", 1, 2, 3],
  ["Account01", "Entity01", "Unit01", 4, 5, 6],
  ["Account01", "Entity01", "Unit01", 7, 8, 9],
  ["Account02", "Entity02", "Unit02", 10, 11, 12],
]
Account01 Entity01 Unit01 12 15 18
Account02 Entity02 Unit02 10 11 12

[download]

In reply to Re: Group by from array by Marshall
in thread Group by from array by sroux

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.