#! /usr/bin/perl
use strict;
use warnings;

use DBI;
use Tk;
use Tk::Optionmenu;

my $db = 'DBI'->connect('dbi:SQLite:dbname=:memory:', "", "",
                        {RaiseError => 1});
$db->do('CREATE TABLE countries (id INT PRIMARY KEY, name TEXT)');
my $insert_countries = $db->prepare(
    'INSERT INTO countries(id, name) VALUES (?, ?)');
$insert_countries->execute(@$_) for [qw[ 1 USA ]], [qw[ 2 Palau ]];

$db->do(<< '__SQL__');
CREATE TABLE states (id   INT PRIMARY KEY,
                     name TEXT,
                     country_id INT,
                     FOREIGN KEY(country_id) REFERENCES countries(id))
__SQL__

my $insert_states = $db->prepare(
    'INSERT INTO states (id, name, country_id) VALUES (?, ?, ?)');
$insert_states->execute(@$_) for [qw[ 1 Alabama 1 ]],
                                 [qw[ 2 Alaska 1 ]],
                                 [qw[ 3 Arizona 1 ]],
                                 [qw[ 4 Koror 2 ]],
                                 [qw[ 5 Melekeok 2 ]];

my %countries;
my $fetch_countries = $db->prepare('SELECT id, name FROM countries');
$fetch_countries->execute;
while (my @row = $fetch_countries->fetchrow_array) {
    $countries{ $row[0] } = $row[1];
}

my $fetch_states = $db->prepare(
    'SELECT id, name FROM states WHERE country_id = ?');

my $mw = 'MainWindow'->new;
my $submenu = $mw->Optionmenu(
    -options => [])->pack;
my $menu = $mw->Optionmenu(
    -options => [map [$countries{$_} => $_], sort keys %countries],
    -command => sub {
        my ($country) = @_;
        $fetch_states->execute($country);
        my %states;
        while (my @row = $fetch_states->fetchrow_array) {
            $states{ $row[0] } = $row[1];
        }
        $submenu->configure(
            -options => [map [$states{$_} => $_], sort keys %states]);
    },
)->pack(-side => 'left');

MainLoop();
[download]

---

---

Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!

Titles consisting of a single word are discouraged, and in most cases are disallowed outright.

Read Where should I post X? if you're not absolutely sure you're posting in the right place.

Please read these before you post! —

• How do I compose an effective node title?
• How do I post a question effectively?
• Markup in the Monastery

Posts may use any of the Perl Monks Approved HTML tags:

a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr

You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)

	For:		Use:
	&		&
	<		&lt;
	>		&gt;
	[		&#91;
	]		&#93;

Link using PerlMonks shortcuts! What shortcuts can I use for linking?

See Writeup Formatting Tips and other pages linked from there for more info.