I was involved in a SO discussion, where the OP wanted to find the emails from certain users, but from a problematic data structure

      [
       {
        foo => {
                browser => "firefox",
                contact => [{ email => "foo\@example.org" }, { phone =
+> 2125551212 }],
                lang    => "en",
               },
       },
       {
        bar => {
                browser => "lynx",
                contact => [{ email => "bar\@example.com" }, { phone =
+> 9125551212 }],
                lang    => "fr",
               },
       },
      ];
[download]

One of the problems is to avoid autovivification.

The usual answers imply

• no autovivifation
• use Data::Diver

but - to my surprise - none of them is core.

after some meditation I came up with the following solution.

It looks so idiomatic and generic to me that I'm asking myself if I missed something:

use v5.12.0;
use warnings;
use Test::More;
use Data::Dump;


sub orig_data {
    return
      [
       {
        foo => {
                browser => "firefox",
                contact => [{ email => "foo\@example.org" }, { phone =
+> 2125551212 }],
                lang    => "en",
               },
       },
       {
        bar => {
                browser => "lynx",
                contact => [{ email => "bar\@example.com" }, { phone =
+> 9125551212 }],
                lang    => "fr",
               },
       },
      ];
}

my $data = orig_data();

my @emails;

# ------ short version
@emails =
  map { $_->{email} // () }
  map { @{ $_->{contact} // [] } }
  map { $_->{bar} // () }
  @$data;

is_deeply(\@emails, ["bar\@example.com"], "result ok");
is_deeply($data, orig_data(), "no autovivification");


# ------ long symmetrical version
@emails =
  map { $_->{email} // () }
  map { @$_ }
  map { $_->{contact} // () }
  my @users =                            # only necessary to check uni
+queness
  map { $_->{bar} // () }
  map { @$_ }
  $data;

is_deeply(\@emails, ["bar\@example.com"], "result ok");
is_deeply($data, orig_data(), "no autovivification");



# --------- this would vivify new elements
# map { $_->{bar}{contact} // () }
#   map { @$_ }
#   $data;

# is_deeply($data, orig_data ,"no autovivification");

done_testing;
[download]

OUTPUT:

ok 1 - result ok
ok 2 - no autovivification
ok 3 - result ok
ok 4 - no autovivification
1..4
[download]

NB: as an extra benefit I can check if @emails and @users have only one element to catch glitches in the data. Those arrays of one element hashes like

• [{ email => "bar\@example.com" }, { phone => 9125551212 }],

are prone to inconsistencies.

Thoughts???

---

---

Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!

Titles consisting of a single word are discouraged, and in most cases are disallowed outright.

Read Where should I post X? if you're not absolutely sure you're posting in the right place.

Please read these before you post! —

• How do I compose an effective node title?
• How do I post a question effectively?
• Markup in the Monastery

Posts may use any of the Perl Monks Approved HTML tags:

a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr

You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)

	For:		Use:
	&		&
	<		&lt;
	>		&gt;
	[		&#91;
	]		&#93;

Link using PerlMonks shortcuts! What shortcuts can I use for linking?

See Writeup Formatting Tips and other pages linked from there for more info.