1. Some of the hex dumps are wrong. Are you sure the file is UTF-8 encoded?
2. To be able to use the characters literally, you need to use utf8 and specify the encoding when openinig the file.

#! /usr/bin/perl
use warnings;
use strict;
use feature qw{ say };
use utf8;

use constant APOSTROPHE => "’" ;
use constant OPENQUOTE  => "“" ;
use constant CLOSEQUOTE => "”" ;
use constant COMMA      => "¸" ;

# Fixed values.
use constant APOSTROPHE2 => "\x{e2}\x{80}\x{99}" ;
use constant OPENQUOTE2  => "\x{e2}\x{80}\x{9c}" ;
use constant CLOSEQUOTE2 => "\x{e2}\x{80}\x{9d}" ;
use constant COMMA2      => "\x{c2}\x{b8}" ;


for my $encoding ("", ':encoding(UTF-8)') {
    open my $self, "<$encoding", __FILE__ or die $!;
    say "Encoding: $encoding";
    while (my $line = <$self>) {
        say "apostrophe in line $." if $line =~ /@{[APOSTROPHE]}/;
        say "open quote in line $." if $line =~ /@{[OPENQUOTE]}/;
        say "close quote in line $." if $line =~ /@{[CLOSEQUOTE]}/;
        say "comma in line $." if $line =~ /@{[COMMA]}/;

        say "apostrophe2 in line $." if $line =~ /@{[APOSTROPHE2]}/;
        say "open quote2 in line $." if $line =~ /@{[OPENQUOTE2]}/;
        say "close quote2 in line $." if $line =~ /@{[CLOSEQUOTE2]}/;
        say "comma2 in line $." if $line =~ /@{[COMMA2]}/;
    }
}
[download]

Encoding: 
apostrophe2 in line 7
open quote2 in line 8
close quote2 in line 9
comma in line 10
comma2 in line 10
Encoding: :encoding(UTF-8)
apostrophe in line 7
open quote in line 8
close quote in line 9
comma in line 10
[download]