As a side note, if you want to support returning false values (such as zero, but particularly undef) easily, return an empty list when the iterator is exhausted. 

sub upto {
   my ( $m, $n ) = @_;
   return sub { 
      return if $m > $n;
      return $m++;
   };
}

[download]

or 

sub upto {
   my ( $m, $n ) = @_;
   return sub { $m <= $n ? $m++ : () };
}

[download]

Then, use a list assignment in scalar/boolean context. 

my $iter = upto( -2, 2 );

while ( my ( $ele ) = $iter->() ) { 
   say $ele;
}

[download]
-2
-1
0
1
2

[download]

You could have used while ( defined( my $i = $iter->() ). But you won't be able to use that for every iterators, such as one that returns the elements of an array: 

sub list {
   my @a = @_;
   return sub { @a ? shift( @a ) : () };
}

my $iter = list( 1, 0, undef, "a" );

# This doesn't work:
# while (  defined( my $ele = $iter->() ) ) {
#    say $ele // "[undef]";
# }

while ( my ( $ele ) = $iter->() ) ) { 
   say $ele // "[undef]";
}

[download]
1
0
[undef]
a

[download]

Since you sometimes need to use the empty-list "trick", you might as well always use it for consistency. Also, it's shorter than using defined :)

In reply to Re: Basic question about Iterator code by ikegami
in thread Basic question about Iterator code by adamsj

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.