BrowserUk:

Here's what I came up with:

#!/usr/bin/env perl
use strict;
use warnings;

for my $X (3 .. 7) {
    for my $Y (2 .. 8) {
        my @orig = ((map {"X$_"} 0 .. $X),(map {"Y$_"} 0 .. $Y));
        my @wanted = ((map {"Y$_"} 0 .. $Y),(map {"X$_"} 0 .. $X));
        print "@orig\n";
        swap($X+1, \@orig, \@wanted);
        my $fl = 'Y';
        for (0 .. $#wanted) {
            if ($orig[$_] ne $wanted[$_]) {
                $fl='N'; $orig[$_]=lc($orig[$_]);
            }
        }
        print "@orig ($fl)\n\n";
    }
}

sub swap {
    my ($ofs, $list) = @_;
    my ($cnt, $src, $dst, $cmp, $tmp);

    $cnt = @$list;
    $dst = $cmp = 0;
    $tmp = $list->[$dst];
    while ($cnt--) {
        $src = ($dst+$ofs) % @$list;
        if ($src == $cmp) {
            # Loop detected, finish it and start next one
            $list->[$dst] = $tmp;
            $dst = ++$cmp;
            $tmp = $list->[$dst];
        }
        else {
            $list->[$dst] = $list->[$src];
            $dst = $src;
        }
    }
}

[download]

The two tricks are: (1) You never have to subtract from your pointers, and (2) you have to detect loops when your pointers have a smaller loop size than the buffer size.

Update: It took me a bit of time to get back to this, and I posted it before reviewing the thread. It turns out that graf already described the algorithm, as did hdb.

...roboticus

When your only tool is a hammer, all problems look like your thumb.

In reply to Re: [OT] Swapping buffers in place. by roboticus
in thread [OT] Swapping buffers in place. by BrowserUk

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.