Having that cleared, now you can concentrate on your regex issue in line 25 ;-)

I thought about your code and there are some other topics:

• use lexical filehandles and the three argument form of open; e.g. see: Perl Maven - Open files in the old way
• avoid "global" variables; e.g. if you need them only as loop variables; use the smallest scope possible; e.g. no my $i; for $i ( ...); better: for my $i ( ... )
• Shouldn't you print $participant only if the regex match was successful
• maybe you can use glob() to find the wanted files?

Here's an untested rewrite based upon these ideas:

#!/usr/bin/perl

# http://perlmonks.org/?node_id=1120387

use strict;
use warnings;


my $log_dir   = '/home/user1';
my $log_file  = "$log_dir/trans.log";

my $trans_dir = '/data/directoy1';


# Log handles
if ( not open my $loghandle, ">>", $log_file ) {        # lexical hand
+le and three argument form of open()
    # syslog ... # what's this?
    die "Cannot open file $log_file: $!";
}



# maybe instead of opendir ... and readdir ...
my @files = grep { -f } glob( "$trans_dir/*OT*" );


foreach my $file (@files) {

   print STDERR "File: $file\n";
   print "$file\n";

   open my $fh, "<", $file                              # same here; l
+exical file handle and 3-arg-form of open()
       or die "Cannot open $file: $!";

   while ( my $line = <$fh> ) {

        if ( (my $participant) = $line =~ m{(.....)/} ) {       # expl
+icitely use $line for regex
            print "$participant";                               # only
+ print when match was found
        }
   }

   close $fh;
}
[download]

---

---

Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!

Titles consisting of a single word are discouraged, and in most cases are disallowed outright.

Read Where should I post X? if you're not absolutely sure you're posting in the right place.

Please read these before you post! —

• How do I compose an effective node title?
• How do I post a question effectively?
• Markup in the Monastery

Posts may use any of the Perl Monks Approved HTML tags:

a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr

You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)

	For:		Use:
	&		&
	<		&lt;
	>		&gt;
	[		&#91;
	]		&#93;

Link using PerlMonks shortcuts! What shortcuts can I use for linking?

See Writeup Formatting Tips and other pages linked from there for more info.