If you exec another program, the running perl is terminated so can't send the alarm.

alarm causes the system to send SIGALRM to the current process.

Don't you have to use system() and kill the child process if it times out?

You can't kill a child if you're waiting for it to exit using system, so you'd have to replace system.

use IPC::Open3 qw( open3 );
use POSIX      qw( WNOHANG );

use constant TIMEOUT => 60;

sub wait_for_test_to_end {
    my ($pid) = @_;

    my $abs_timeout = time() + TIMEOUT;
    while (1) {
        return if waitpid($pid, WNOHANG) > 0;
        last if time() > $abs_timeout;
        sleep(1);
    }

    kill(ALRM => $pid);

    $abs_timeout = time() + 15;
    while (1) {
        return if waitpid($pid, WNOHANG) > 0;
        last if time() > $abs_timeout;
        sleep(1);
    }

    kill(KILL => $pid);
    waitpid($pid, 0);
}

while (1) {
    for my $runCommand (@runArray) {
        $forkMgr->start($runCommand)
            and next;

        my $pid = open3('<&STDIN', '>&STDOUT', '>&STDERR',
            "/usr/localcw/opt/patrol/nagios/libexec/$runCommand");
        wait_for_test_to_end($pid);
        $forkMgr->finish($? & 0x7F ? 0x80 | ($? & 0x7F) : $? >> 8);
    }

    $forkMgr->wait_all_children;

    sleep 10;
}
[download]

And you're back to having a useless process between the manager than the test.

On the plus side, you can use more complex conditions than a simple timeout. You can also forcibly kill the process if it doesn't respond to SIGALRM as the above demonstrates.

---

---

Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!

Titles consisting of a single word are discouraged, and in most cases are disallowed outright.

Read Where should I post X? if you're not absolutely sure you're posting in the right place.

Please read these before you post! —

• How do I compose an effective node title?
• How do I post a question effectively?
• Markup in the Monastery

Posts may use any of the Perl Monks Approved HTML tags:

a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr

You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)

	For:		Use:
	&		&
	<		&lt;
	>		&gt;
	[		&#91;
	]		&#93;

Link using PerlMonks shortcuts! What shortcuts can I use for linking?

See Writeup Formatting Tips and other pages linked from there for more info.