Use this script on a windows system to recursively list all files on a network shared drive (or a local directory if you wish). Change the value of $outfname and @startpath before you run it.

The files are listed with meta-data. First column contains the file size, or total size of files conained in a directory, followed by an indicator of the file type: "/" for a directory, "@" for a symlink, "~" for a symlink to directory, "?" for error in lstat, "!" for error in opendir. The latter two markers could show up when files are deleted while you are producing the listing. Second column is creation date, third column is modification date, last is filename and, for symlinks, link target. 

#!perl
use warnings; use 5.016;
use Time::HiRes (); use Encode; 
use Win32::LongPath (); 
use Unicode::Collate ();

our $outfname = q(C:\somedir\list.txt);
our @startpath = (
    "\\\\HOSTNAME\\sharename",
);

open our$outf, ">:encoding(utf8)", $outfname or die;
our $pro_count = 0; our $pro_time = Time::HiRes::time();
our $pro_gran = 1251;
our $coll = Unicode::Collate->new;

sub visit {
    my($path, $addto_ref) = @_;
    my$stat = Win32::LongPath::lstatL($path);
    my$isdir = $stat && 0 != (0x10 & $$stat{attribs}); 
    my$islink = $stat && 0 != (0x400 & $$stat{attribs});
    my$typestr = !$stat ? "?" : $islink ? ($isdir ? "~" : "@") : $isdi
+r ? "/" : " ";
    my$mdatestr = "?"; my$cdatestr = "?";
    if ($stat) { 
        my($ms,$mm,$mh,$md,$mb,$my) = gmtime($$stat{ctime}); 
        $mdatestr = sprintf "%04d-%02d-%02d", 1900+$my, 1+$mb, $md;
        my($cs,$cm,$ch,$cd,$cb,$cy) = gmtime($$stat{mtime}); 
        $cdatestr = sprintf "%04d-%02d-%02d", 1900+$cy, 1+$cb, $cd;
    }
    my$readlink = $islink ? Win32::LongPath::readlinkL($path) : undef(
+);
    my$linkstr = defined($readlink) ? "\t>" . $readlink : "";
    my$size = $stat ? 0 + $$stat{size} : 0;
    if (!$islink && $isdir) {
        my$dh = Win32::LongPath->new; my$ok = $dh->opendirL($path);
        if ($ok) {
            $^E = 0;
            my@n = $dh->readdirL;
            if (18 != $^E) { warn qq(warning: readdir "$path" $^E ), 0
++$^E; }
            @n = $coll->sort(@n);
            $dh->closedirL;
            for my$n (@n) {
                "." eq $n || ".." eq $n and next;
                if (!length($n) || $n =~ y|/\\||) { 
                    warn qq(wtf strange name in directory: "$path" "$n
+"); next; 
                }
                my$p = $path . "\\" . $n;
                my$a = \$size;
                visit($p, $a);
            }
        } else {
            $typestr = "!";
        }
    }
    $$addto_ref += $size;
    printf $outf "%12d%1s %10s %10s %s%s\n", 
        $size, $typestr, $mdatestr, $cdatestr, $path, $linkstr;
    $outf->flush;
    if (0 == ++$pro_count % $pro_gran) {
        my$n = Time::HiRes::time();
        my$d = $n - $pro_time;
        printf STDERR qq(progress %9d %.2f "%s"), $pro_count, $d, enco
+de_utf8($path);
        Time::HiRes::sleep(0.9 + 2.2 * abs($d));
        printf STDERR qq(;\n);
        $pro_time = Time::HiRes::time();
    }
}
for my$p (@startpath) { 
    warn qq(starting from "$p");
    my$total_sz = 0;
    visit($p, \$total_sz) 
}
warn qq(lsrecursive all done.);

__END__

[download]

Update: changed text to describe ascended bug in the program where the ctime and mtime were swapped.

In reply to Recursively list all files on a network shared drive on windows by ambrus

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.