However, I have reason to keep the Base object inside {Parent}, as there are other constructors which will be invoked by other methods in Lite class.

There's a better way to do that by making the constructor in the parent class subclass-friendly. This involves checking the first argument you get in an OO constructor routine and identifying if it has a valid ref() associated with it. If you write your constructors as my example code below shows, you'll be making life easy for anyone else who wants to built on your code base.

In the code below, note a couple of things:

  1. Note that the $ex2 object in consumer.pl is created by using the constructor method of the $ex1 object, which is of the "Improved" subclass.
  2. See how the Parent class uses the ref() call to correctly determine when a subclass is re-using the Parent's constructor method.

Here's the example code structure:

File: consumer.pl

use strict;
use warnings;
use lib '.';
require Ex::Improved;

my $ex1 = Ex::Improved->new();
# Show that the parent's constructor still works:
my $ex2 = $ex1->new();

$ex1->setColor('green');
$ex1->setFood('bean');

$ex2->setColor('red');
$ex2->setFood('radish');

my $count = 0;    # count each object we display
for my $obj ($ex1, $ex2) {
    printf "Object: %d\n", ++$count;
    printf "Color: %s\n", $obj->getColor();
    printf "Food: %s\n", $obj->getFood();
}

[download]

File: Ex/Parent.pm (the parent class)

package Ex::Parent;
use strict;
use warnings;

sub new {
    my $class = shift;
    # This line lets subclass-created objects work:
    $class = ref($class) || $class;
    return bless { }, $class;
}

sub getColor {
    my $self = shift;
    return $self->{color} // undef;
}

sub setColor {
    my $self = shift;
    $self->{color} = shift or return 0;
    return 1;
}

1;

[download]

File: Ex/Improved.pm (the subclass)

package Ex::Improved;
use strict;
use warnings;
use parent 'Ex::Parent';

# This "improved" class lets callers get/set Food too!

sub getFood {
    my $self = shift;
    return $self->{food} // undef;
}

sub setFood {
    my $self = shift;
    $self->{food} = shift or return 0;
    return 1;
}

1;

[download]

In reply to Re^3: Inheritance confused by Apero
in thread Inheritance confused by exilepanda

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.