Here's a database solution showing the flexibility by adding the weighted average

#!perl
use strict;
use DBI;

# create table
my $dbh = create_db('database.sqlite');

# load data
my @files = qw(fileA.txt fileB.txt);  
for my $file (@files){
  load_db($dbh,$file);
}

# report
my $query = 'SELECT A,B,C,D,AVG(E),SUM(F),
             MIN(E),MAX(E),COUNT(*),SUM(E*F)/SUM(F)
             FROM test
             GROUP BY A,B,C,D
             ORDER BY A,B,C,D';
report($dbh,$query);

[download]
sub report {  
  my ($dbh,$sql) = @_;
  my $ar = $dbh->selectall_arrayref($sql);
  print join "\t",qw(A B C D Avg Sum Min Max Count WeightedAvg),"\n";
  for (@$ar){
    print join "\t",@$_,"\n";
  }
}

sub load_db {
  my ($dbh,$filename) = @_;
  open IN,'<',$filename or die "$!";
  
  my $sql = 'INSERT INTO test VALUES (?,?,?,?,?,?)';
  my $sth = $dbh->prepare($sql);
  my $n = 0;
  while (<IN>){
    next unless (/\S/); # skip blank lines
    my @f = split;
    $sth->execute(@f);
    ++$n;
  }
  print "$n records insert from $filename\n";
  close IN;
}

sub create_db {
  my $dbfile = shift;
  unlink($dbfile) if (-e $dbfile);

  my $dbh = DBI->connect(         
    "dbi:SQLite:dbname=$dbfile", 
    "", "", { RaiseError => 1 }       
    ) or die $DBI::errstr;

  my $sql = "CREATE TABLE test (
    A,B INTEGER,C,D,E REAL,F REAL)";

  $dbh->do($sql) or die $DBI::errstr;
  return $dbh;
}

[download]
poj

In reply to Re^3: Merging partially duplicate lines by poj
in thread Merging partially duplicate lines by K_Edw

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.