Hi ravi45722

You are a little mixed up; you've copied code snippets meant to illustrate different things and patched them together, but the result doesn't make sense.

Your package will contain the constructor sub new() and your script that uses the package will call new() to create an instance of the object.

Also, even though that tutorial shows package 'File' as an example, it's customary to avoid single-word package names unless they are distinctive; you would be safer with either MyFile or My::File.

Update in response to OP's reply:

Are you sure you're ready to tackle OOP in Perl? Have you already become familiar with packages in general? Here's a simple example of a package in a module and a script that uses it, download it and try it out:

# DayPredict.pm
# maps moods to predictions

package DayPredict;
use strict; use warnings;

sub predict {
    my $mood = shift;
    if ( $mood eq 'happy' ) {
        return 'be great';
    } elsif ( $mood eq 'sad' ) {
        return 'get better';
    } else {
        return; # didn't get a mood so return undef
    }
}

1; # module must return a true value
[download]

#!/usr/bin/perl

# predict_day.pl
# Tells what sort of day you will have based on your mood

use strict; use warnings; use feature 'say';

use DayPredict;

my $mood = $ARGV[0] or die "no mood!";

my $prediction = DayPredict::predict( $mood );

if ( $prediction ) {
    say 'Your day will ' . $prediction . ', do not worry.';
} else {
    say 'Cannot read your mood so unable to predict your day.';
}

__END__
[download]

Usage:

$ perl predict_day.pl happy
[download]

Now if you wanted to do the same thing with OOP, making an object for your day, you might do something like this:

# MyDay.pm
# Interface to objects representing days

package MyDay;

use strict; use warnings;

sub new {
    # This is boilerplate code you can copy.
    # But you'd be better off with a module so you don't have to do it
+ by hand.
    # Check out Class::Tiny or Moo

    my $proto = shift;
    my $class = ref($proto) || $proto;
    my $self  = {};
    bless ($self, $class);
    return $self;
}

sub mood {
    my $self = shift;

    # If there's an argument provided, set the value,
    # then in either case, return the current value.
    if ( @_ ) { 
        $self->{'mood'} = shift;
    }
    return $self->{'mood'};
}

sub predict {
    my $self = shift;
    my $prediction;

    # Get the mood by calling the mood() method on your object
    # ... referred to as $self here while you're inside it
    if ( $self->mood eq 'happy' ) {
        $prediction = 'be great';
    } elsif ( $self->mood eq 'sad' ) {
        $prediction = 'get better';
    }
    return $prediction; # undef if no mood
}

1; # module must return a true value
[download]

#!/usr/bin/perl
use strict; use warnings; use feature 'say';

# my_day.pl - predicts your day based on your mood

use MyDay;

my $mood = $ARGV[0] or die "no mood!";

my $day = MyDay->new; # construct a new object

$day->mood( $mood ); # set the value of the object attribute
                     # based on this script's argument

my $prediction = $day->predict; # call the predict() method on the obj
+ect,
                                # which contains your mood stored with
+in it.

if ( $prediction ) {
    say 'Your day will ' . $prediction . ', do not worry.';
} else {
    say 'Cannot read your mood so unable to predict your day.';
}

__END__
[download]

Usage:

$ perl my_day.pl sad
[download]

Hope this is a little clearer now!

Update: Changed 'package must return a true value' to 'module must return a true value', thanks Discipulus.

---

---

Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!

Titles consisting of a single word are discouraged, and in most cases are disallowed outright.

Read Where should I post X? if you're not absolutely sure you're posting in the right place.

Please read these before you post! —

• How do I compose an effective node title?
• How do I post a question effectively?
• Markup in the Monastery

Posts may use any of the Perl Monks Approved HTML tags:

a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr

You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)

	For:		Use:
	&		&
	<		&lt;
	>		&gt;
	[		&#91;
	]		&#93;

Link using PerlMonks shortcuts! What shortcuts can I use for linking?

See Writeup Formatting Tips and other pages linked from there for more info.