One possible solution is to check @- and @+:

use warnings;
use strict;

sub calcit {
    my $in = shift;
    my %rules = (A => 1,B => 1,C => 0,D => 1);    
    my ($s,$s1,$s2) = (0)x3;
    while ($in=~/(\d+)([ABCD])/g) {    
        my ($n,$op) = ($1,$2);
        $s += $n * $rules{$op};
        $s1 += $n * $rules{$op}
            unless $op eq 'D' && $-[0]>0;
        $s2 += $n * $rules{$op}
            unless $op eq 'D' && $+[0]<length($in);
    }
    return ($s,$s1,$s2);
}

use Test::More;
is_deeply [calcit("2D40A2C1B4D")], [47,43,45], "2D40A2C1B4D";
is_deeply [calcit("2D40A2C1B")],   [43,43,41], "2D40A2C1B";
done_testing;

[download]

But TIMTOWTDI, for example you could ignore all "D" codes in the initial processing of the string and then use a separate regex (/^(\d+)D/ resp. /(\d+)D$/) to account for them.

In reply to Re: Detecting position of a substring within a string by Anonymous Monk
in thread Detecting position of a substring within a string by K_Edw

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.