First, a couple of things: Always use warnings;. Avoid using $_[0] etc. directly unless you know why you need to, instead do sub foo { my ($x,$y,$z) = @_; ... }. Don't turn off strict for the whole module, just do it in as small a scope as possible. (And in fact, in this case, you don't even need to turn it off at all, since you're not accessing subroutines via their name, you're accessing them via a code reference, e.g. \&get_locations.)

In general, you probably should study perlreftut and perlref. The way to call a code reference is $coderef->($arg1, $arg2, ...), where $coderef can also be a complex dereference consisting of hashes, arrays, and calls to other code references.

# ---8<--- ProcessData.pm ---8<---
package ProcessData;
use warnings;
use strict;
use Carp;

sub new {
    my ($class) = @_;
    my $self = { _dispatch_table => {} };
    return bless $self, $class;
}

sub add_subroutine {
    @_==3 or croak "Insufficient arguments passed to add_subroutine().
+";
    my ($self,$name,$code) = @_;
    croak "The reference passed to add_subroutine() is not a CODE refe
+rence."
        unless ref $code eq "CODE";
    $self->{_dispatch_table}{$name} = $code;
}

sub process_data {
    @_==2 or croak "Insufficient arguments passed to process_data().";
    my ($self,$name) = @_;
    $self->{_dispatch_table}{$name}->();
}

sub process_locations {
    my ($self) = @_;
    $self->process_data("locations");
}

1;

# ---8<--- test.pl ---8<---
use warnings;
use strict;
use ProcessData;

my $pd = ProcessData->new();
$pd->add_subroutine("locations", \&get_locations);
$pd->process_locations;

sub get_locations { print "get_locations...\n" }

[download]

In reply to Re: Is it possible to call a package::main subroutine from a module? by Anonymous Monk
in thread Is it possible to call a package::main subroutine from a module? by TorontoJim

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.