The main reasons I like/use Moo, etc, are to share behavior in a larger application (like a Catalyst application where the model is needed by the controllers, the tests, and the command line) and to wrap up, normalize, and auto-document, complex behaviors of conjoined simple parts that would otherwise quickly become spaghetti; make things like push and @{$object->{bunch_of_data}} semantic, less dense. This web spider stub is off the top of my head so take it as a terse draft but it shows the kinds of things I like to do–

package MooSpider;
use Moo;
use MooX::HandlesVia;
use Carp;
our $VERSION = "42";

has "_pages" =>
    is => "ro",
    handles_via => "Array",
    default => sub { [] },
    handles => {
        pages => "elements",
        queue_page => "push",
        next_page => "shift",
    };

has "agent" =>
    is => "lazy",
    isa => sub { confess "Need a flavor of WWW::Mechanize"
                     unless eval { $_[0]->isa("WWW::Mechanize") } },
    handles => [qw/ get post request links uri success response /];

sub _build_agent {
    require WWW::Mechanize;
    WWW::Mechanize->new( autocheck => 0,
                         agent => join("/", __PACKAGE__, $VERSION) );
}

sub crawl {
    my $self = shift;
    return unless my $uri = shift || $self->next_page;
    if ( $self->get($uri) and $self->success )
    {
        $self->queue_page($_->url_abs) for $self->links;
    }
    else
    {
        carp "Problem fetching ", $self->uri, $/,
            "Moving on to next link";
        $self->crawl;
    }
    $self->response;
}

1;

my $spider = MooSpider->new;
$spider->crawl("http://example.org");
print join($/, $spider->pages), $/;
$spider->crawl;
print join($/, $spider->pages), $/;

[download]

In reply to Re^3: Bullish on Moose, how about you? by Your Mother
in thread Bullish on Moose, how about you? by nysus

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.