As mentioned before, please try to remove unrelated parts of the code from your samples to make it more readable. Getting into practice of using strict and warnings would also save you a lot of trouble.

#!/usr/bin/perl
use warnings;
use strict;

use Tk;

my %metal_name    = map { $_ => "M$_" } 1 .. 4;
my $default_metal = 3;
my $default_x     = 42;
my $default_y     = 3.14;

my $mw = 'MainWindow'->new(-title => 'entries and option menu');

my $f_metal = $mw->Frame->pack;
my $o_metal = $f_metal->Optionmenu(
    -options      => [ map [ $metal_name{$_} => $_ ],
                       sort keys %metal_name ],
    -variable     => \ my $metal,
    -textvariable => \ my $t_metal,
)->pack;

# Set the default option.
$metal   = $default_metal;
$t_metal = $metal_name{$default_metal};


my $f_coord = $mw->Frame->pack;
$f_coord->Label(-text => 'X:')->pack(-side => 'left');

# Setting the default entry values.
my $e_x = $f_coord->Entry(-textvariable => \(my $x = $default_x))
                         ->pack(-side => 'left');
my $e_y = $f_coord->Entry(-textvariable => \(my $y = $default_y))
                         ->pack(-side => 'right');

$f_coord->Label(-text => 'Y:')->pack(-side => 'right');

my $f_txt = $mw->Frame->pack;
my $txt   = $f_txt->Scrolled('Text')->pack;

my $f_go = $mw->Frame->pack;
$f_go->Button(-text    => 'Go!',
              -command => sub {
                  $txt->insert(end => join "\n",
                                      "Metal: $metal_name{$metal}",
                                      "Coords: [ $x, $y ]", q());
              },
)->pack;

MainLoop();
[download]

($q=q:Sq=~/;[c](.)(.)/;chr(-||-|5+lengthSq)`"S|oS2"`map{chr |+ord
}map{substrSq`S_+|`|}3E|-|`7**2-3:)=~y+S|`+$1,++print+eval$q,q,a,
[download]