This might be useful for sysadmins who manage Solaris servers. The iostat -En command can be used to check for cumulative disk errors but the output is rather dense so it can be difficult to sort the wood from the trees. This script uses Term::ANSIColor to make errors easier to spot.

use strict;
use warnings;

use Term::ANSIColor qw{ :constants };

my $rxTriggers = do {
   my @triggers = (
      q{Soft Errors: },
      q{Hard Errors: },
      q{Transport Errors: },
      q{Media Error: },
      q{Device Not Ready: },
      q{No Device: },
      q{Recoverable: },
      q{Illegal Request: },
      q{Predictive Failure Analysis: },
      );
   local $" = q{|};
   qr{(@triggers)(\d+)}
   };

my @iostatCmd = qw{ /usr/bin/iostat -En };
open my $iostatFH, q{-|}, @iostatCmd
   or die qq{open: @iostatCmd |: $!\n};

print q{-} x 60, qq{\n};
while ( not eof $iostatFH )
{
    my $record;
    $record .= $_ for
       map { eof $iostatFH ? () : scalar <$iostatFH> }
       1 .. 5;

    substr $record, 16, 0, RESET;
    substr $record,  0, 0, BOLD;
    $record =~
       s{$rxTriggers}
        { $2 eq q{0}
          ? $1 . GREEN . $2 . RESET
          : YELLOW . $1 . RED . $2 . RESET }eg;

    print $record;
    print q{-} x 60, qq{\n};
}

close $iostatFH
   or die qq{close: @iostatCmd |: $!\n};

[download]

I no longer have a working Solaris box to provide example output but I hope this will be useful for somebody out there.

Cheers,

JohnGG

In reply to Solaris: make iostat output clearer by johngg

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.