So... one of my distribution relies heavily on other distributions I've written, and it's hard to ensure my dependencies for my own modules are up-to-date in the prerequisite list in the build system. Sometimes I forget to bump a prereq before I do a release, which means I have to immediately do a one-line release the next day, because I'll have emails from CPAN Testers because tests are failing.

I've been toying with a few ways to automatically check this for me. Below is one such hack I came up with. There's two vars that need to be set: $dist and $author. It then pulls the distribution from the CPAN, extracts all of it's prerequisite dependency information. Then, it fetches the list of all distributions I've put on the CPAN, and creates a dist/version hash.

Note that this compares *only* the prereqs that I personally have uploaded. It'd be trivial to modify a bit to check them all.

After the data is collected, it iterates the known dependencies, and if there's a match with one of my own other distributions, I compare versions. Currently, it just prints out the list, but I'm going to hack this into my Test::BrewBuild system as another command line option so that every build run, I'll be notified of any discrepancies. Eventually, I'll likely make it auto-update the Makefile.PL files for me with the new dep versions, as well as have it review the prereq versions in the current repo of the dist I'm working on, instead of comparing to the latest CPAN release, so I can correct the issues *before* pushing to PAUSE :)

use warnings;
use strict;

use MetaCPAN::Client;

my $c = MetaCPAN::Client->new;

my $dist = 'RPi-WiringPi';
my $author = 'STEVEB';

check_deps($dist, $author);

sub check_deps {
    my ($dist, $author) = @_;

    if ($dist =~ /:/){
        die "\$dist must be hyphenated... don't use ::\n";
    }

    my $release = $c->release($dist);
    my $deps = $release->{data}{dependency};

    my $author_modules = author_modules($author);

    for my $dep (@$deps){
        my $dep_mod = $dep->{module};
        my $dep_ver = $dep->{version};

        if (exists $author_modules->{$dep_mod}){
            my $cur_ver = $author_modules->{$dep_mod};
            print "$dep_mod: \n" .
                  "\tdep ver: $dep_ver\n" .
                  "\tcur ver: $cur_ver\n\n";
        }
    }
}
sub author_modules {
    my ($author) = @_;

    my $query = {
        all => [
            { author => $author },
            { status => 'latest' },
        ],
    };

    my $limit = { 
        '_source' => [
            qw(distribution version)
        ] 
    };

    my $releases = $c->release($query, $limit);

    my %rel_info;

    while (my $rel = $releases->next){
        my $dist = $rel->distribution;
        $dist =~ s/-/::/g;
        $rel_info{$dist} = $rel->version;
    }

    return \%rel_info;
}

[download]

Output:

perl perl/dependency_version_compare/compare.pl

RPi::DigiPot::MCP4XXXX: 
    dep ver: 2.3603
    cur ver: 2.3603

RPi::BMP180: 
    dep ver: 2.3603
    cur ver: 2.3603

RPi::ADC::MCP3008: 
    dep ver: 2.3603
    cur ver: 2.3603

RPi::SPI: 
    dep ver: 2.3606
    cur ver: 2.3606

RPi::DAC::MCP4922: 
    dep ver: 2.3604
    cur ver: 2.3604

RPi::WiringPi::Constant: 
    dep ver: 0.02
    cur ver: 0.02

RPi::DHT11: 
    dep ver: 1.02
    cur ver: 1.02

WiringPi::API: 
    dep ver: 2.3609
    cur ver: 2.3609

RPi::ADC::ADS: 
    dep ver: 1.01
    cur ver: 1.01

[download]

In reply to Automatically ensure your CPAN dists have up-to-date prereq version numbers by stevieb

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.