nysus recently asked whether there was a way to get at all the currently open filehandles. Together with Discipulus I concocted a module which does that. It records open, close along with their respective time, and drops filehandles from the track record as soon as they get undefined or go out of scope.

package FileHandle::Track;
use Time::HiRes qw(gettimeofday);

use Hash::Util::FieldHash qw(id_2obj);

my %fd;

BEGIN{
    Hash::Util::FieldHash::fieldhash %fd;
    my $open = sub {
        @_ > 2 ? open $_[0],$_[1],$_[2] : open $_[0], $_[1];
    };
    my $close = sub { close $_[0] };

    *CORE::GLOBAL::open = sub {
        my $result = $open->(@_);
        if ($result) {
            $fd{$_[0]}->{open}     = join " ",@_[1,2],caller;
            $fd{$_[0]}->{opentime} = join ".", gettimeofday;
        }
        $result;
    };
    *CORE::GLOBAL::close = sub {
        my $result = $close->(@_);
        $fd{$_[0]}->{close} = join " ", caller;
        if ($result) {
            $fd{$_[0]}->{close} .= " (closed)";
        } else {
            $fd{$_[0]}->{close} .= " (close failed)";
        }
        $fd{$_[0]}->{closetime} = join ".", gettimeofday;
        $result;
    };
}

sub get_fds {
    return { map { id_2obj($_), $fd{$_} } keys %fd };
}

[download]

After making that into a module proper (tests, documentation with due credits) I'll upload that to cpan.

Any suggestions, critics, enhancements?

perl -le'print map{pack c,($-++?1:13)+ord}split//,ESEL'

In reply to Track open file handles by shmem

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.