Ah, upon closer inspection, the reason the END block isn't called is from the KILL line.

 # $SIG{HUP} = $SIG{INT} = $SIG{QUIT} = $SIG{TERM} = sub {
 #    $SIG{INT} = $SIG{$_[0]} = sub { };
 #
 #    CORE::kill($_[0], $_is_MSWin32 ? -$$ : -getpgrp);
 #    for my $_i (1..15) { sleep 0.060 }
 #
 #    CORE::kill('KILL', $$);
 #    CORE::exit(255);
 # };

[download]

There is no guarantee to which END block is called first by Perl. MCE::Shared has an END block to notify the shared-manager to exit. The script will stall had Perl called that one first. Therefore, leave intact the sig handling bits at the application level. The END block is not necessary. But simply added to see workers enter it.

use strict; use warnings; use feature 'say';
use Data::Dumper; ++$Data::Dumper::Sortkeys;
use Time::HiRes 'sleep';
use MCE::Loop;
use MCE::Shared;
$|++;

my $pid = $$; say "PID $pid";
my $hash = MCE::Shared->hash();

$SIG{'INT'} = $SIG{'TERM'} = sub {
    my $signal = shift; $SIG{'INT'} = $SIG{'TERM'} = sub {};
    say "Hello from $signal: $$";
    say 'Parent is ready to dump';
    say 'Dumping: ' . Dumper $hash->export;
    MCE::Signal::stop_and_exit('INT');
};

MCE::Loop->init(
    max_workers => 2, chunk_size => 1, user_begin => sub {
        $SIG{'INT'} = sub {
            my $signal = shift;
            say "Hello from $signal: $$";
            MCE->exit(0);
        };
        $SIG{'TERM'} = sub {
            my $signal = shift;
            say "Hello from $signal: $$";
            MCE::Signal::stop_and_exit($signal);
        };
    }
);

mce_loop {
    my ( $mce, $chunk_ref, $chunk_id ) = @_;
    say sprintf 'Forked worker in slot %s with pid %s for chunk %s', M
+CE->wid, MCE->pid, $chunk_id;
    for ( @{ $chunk_ref } ) {
        $hash->{ sprintf '%.2d %s', $_, $$ } = time;
        say "After $_: " . Dumper $hash->export;
        sleep 3;
    }
} ( 0 .. 12 );

MCE::Loop->finish;

END {
    say "Hello from END block: $$";
    if ($$ == $pid) {
        say "Parent is ready to dump";
        say 'Dumping: ' . Dumper $hash->export;
    }
}

[download]

I will make a new MCE::Shared update after more testing. Thank you, 1nickt.

In reply to Re^2: Interrupt multi-process program while using MCE::Shared hash: END block code does not (all) run by Anonymous Monk
in thread Interrupt multi-process program while using MCE::Shared hash: END block code does not (all) run by 1nickt

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.