Hello gowthamvels,

When manipulating tabular data, I often like to use the Data::Table module. I noticed a potential problem with your input data. It had two columns named col4. So, I edited the header of your data such that the columns you want to calculate sums for are col7 and col8. If your data is in data.csv as follows, 
col1,col2,col3,col4,col5,col6,col7,col8
1234,GP,20170715,0,V,97517,24,0.6
5678,Pack,20170715,0,V,97516,88,1.8
1234,GP,20170715,0,V,97517,22,0.6
5678,Pack,20170715,0,V,97517,183,3.9
1234,PRS,20170715,0,S,97517,261,5.4
5678,PRS,20170715,0,M,97517,36,0.9

[download]
then the following code will result in the output that you want. 
#!/usr/bin/env perl

use strict;
use warnings;

use Data::Table;

# Load input data from csv file
my $dt = Data::Table::fromCSV('data.csv');

# Make a new table that only contains the relevant columns
my $st = $dt->subTable(undef, [ 'col2', 'col7', 'col8' ]);
 
# Group by 'col2', calculate sums for 'col7' and 'col8'
my $ot = $st->group(
    ['col2'], # column to group by
    ['col7', 'col8'], # Columns to perform calculation on
    [ \&sum, \&sum ], # Apply sum function to 'col7' and 'col8'
    ['sum_of_col7', 'sum_of_col8'] # Put the sums in these columns 
);
print $ot->csv, "\n";

sub sum {
  my @data = @_;
  my $sum = 0;
  foreach my $x (@data) {
    next unless $x;
    $sum += $x;
  }
  return $sum;
}

exit;

[download]
The output is 
col2,sum_of_col7,sum_of_col8
GP,46,1.2
Pack,271,5.7
PRS,297,6.3

[download]

In reply to Re: group by and sum for two columns by kevbot
in thread group by and sum for two columns by gowthamvels

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.