As previously mentioned, process STDIN and $rx_q in separate threads. But also, use dequeue instead of dequeue_nb. 

use strict;
use warnings qw( all );
use threads;

use Thread::Queue qw( );   # 3.01+

use constant NUM_WORKERS => 10;

sub worker {
   my ($job) = @_;
   return "[$job]";
}

sub collector {
   my ($job) = @_;
   print "{$job}\n";
}

{
   my $tx_q = Thread::Queue->new();
   my $rx_q = Thread::Queue->new();
   
   my @workers;
   for (1..NUM_WORKERS) {
      push @workers, async {
         while (defined( my $job = $tx_q->dequeue() )) {
            $rx_q->enqueue(worker($job));
         }
      };
   }
   
   my $collector_thread = async {
      while (defined( my $job = $rx_q->dequeue() )) {
         collector($job);
      }
   };

   while (my $job = <>) {
      chomp($job);
      $tx_q->enqueue($job);
   }

   $tx_q->end();
   $_->join() for @workers;

   $rx_q->end();
   $collector_thread->join();
}

[download]

In reply to Re: Threading with a twist by ikegami
in thread Threading with a twist by scorpion7

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.