Use a while loop to validate the input, use subroutines for submenus. The return value of the submenu can be used to decide whether to quit or continue, i.e. back or quit.

#! /usr/bin/perl
use warnings;
use strict;
use feature qw{ say };

my $done;
while (! $done) {
    print << '__MENU__';
Main Menu
  1. Get date and time
  2. Go to submenu
  3. Quit
__MENU__

    chomp( my $reply = <> );
    next unless $reply =~ /^[123]$/;

    if ($reply == 1) {
        say scalar localtime;

    } elsif ($reply == 2) {
        $done = submenu();

    } else {
        $done = 1;
    }

}

sub submenu {
    my $done;
    while (! $done) {
        print << '__MENU__';
Submenu
  1. Get username
  2. Back
  3. Quit
__MENU__

        chomp( my $reply = <> );
        next unless $reply =~ /^[123]$/;

        if ($reply == 1) {
            say scalar getpwuid $>;

        } else {
            $done = $reply;
        }
    }
    return $done == 3
}

[download]

As you probably noticed, most of the code is repeated, so it should be extracted to a subroutine.

Update: 

#! /usr/bin/perl
use warnings;
use strict;
use feature qw{ say };


menu('Main Menu',
     [ 'Get date and time', sub { say scalar localtime } ],
     [ 'Go to submenu',     sub { $_[0] = submenu() } ],
     [ 'Quit',              sub { $_[0] = 1 } ],
);


sub menu {
    my ($title, @options) = @_;

    my $done;
    while (! $done) {
        say $title;
        say 1 + $_, ".  $options[$_][0]" for 0 .. $#options;

        chomp( my $reply = <> );
        next unless $reply =~ /^[1-9][0-9]*$/;
        next if $reply > @options;

        --$reply;
        $options[$reply][1]->($done, $reply);
    }
    return $done
}


sub submenu {
    my $result = menu('Submenu',
         [ 'Get username', sub { say scalar getpwuid $> } ],
         [ 'Back',         \&pass ],
         [ 'Quit',         \&pass ],
    );
    return $result == 2  # Propagate Quit.
}


sub pass { $_[0] = $_[1] }

[download]
($q=q:Sq=~/;[c](.)(.)/;chr(-||-|5+lengthSq)`"S|oS2"`map{chr |+ord
}map{substrSq`S_+|`|}3E|-|`7**2-3:)=~y+S|`+$1,++print+eval$q,q,a,

[download]

In reply to Re: New to Perl and need help by choroba
in thread New to Perl and need help by Narbawlz

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.