Thanks for the pointer the Graph::Easy, I'd not seen that before so just installed it. I'd already created a hash of edges from an AoA of the events but had no idea how to turn them into a graph as I don't have a computer science background. Once I had the module I initialised a graph and added the edges from the hash and printed the result. My output differs from yours in that you have two 1 -> 2 edges where I only have one. Reading the module documentation it may be that you did $graph->add_edge(1,2) twice, although it only appears once in the code you posted.

use strict;
use warnings;

use 5.022;

use Graph::Easy;
say qq{Using Graph::Easy version $Graph::Easy::VERSION};

my @events = (
   [ 1, 2, 5, 6, 7, 8, 9, 11 ],
   [ 1, 2, 5, 6, 7, 8, 10, 11 ],
   [ 1, 4, 5, 6, 7, 8, 9, 11 ],
   [ 1, 4, 5, 6, 7, 8, 10, 11 ],
   [ 1, 3, 5, 6, 7, 8, 9, 11 ],
   [ 1, 3, 5, 6, 7, 8, 10, 11 ],
   [ 1, 7, 8, 10, 11 ],
   );

my %edges;
foreach my $event ( @events )
{
    foreach my $idx ( 1 .. $#{ $event } )
    {
        $edges{ join q{ -> }, $event->[ $idx - 1 ], $event->[ $idx ] }
+ ++;
    }
}

say for
   map { unpack q{x8a*} }
   sort
   map { pack q{NNa*}, split( m{ -> } ), $_ }
   keys %edges;

my $graph = Graph::Easy->new();
$graph->add_edge( split m{ -> } ) for keys %edges;

print $graph->as_ascii();
[download]

The output.

Using Graph::Easy version 0.76
1 -> 2
1 -> 3
1 -> 4
1 -> 7
2 -> 5
3 -> 5
4 -> 5
5 -> 6
6 -> 7
7 -> 8
8 -> 9
8 -> 10
9 -> 11
10 -> 11

  +-----------------------------+
  |                             |
  |                             |
  |         +-------------------+-------------------+
  |         |                   v                   v
+---+     +---+     +---+     +---+     +---+     +---+     +---+     
++----+     +----+
| 4 | <-- | 1 | --> | 2 | --> | 5 | --> | 6 | --> | 7 | --> | 8 | --> 
+| 10 | --> | 11 |
+---+     +---+     +---+     +---+     +---+     +---+     +---+     
++----+     +----+
            |                   ^                             |       
+             ^
            |                   |                             |       
+             |
            v                   |                             v       
+             |
          +---+                 |                           +---+     
+             |
          | 3 | ----------------+                           | 9 | ----
+-------------+
          +---+                                             +---+
[download]

If I change the graphing code to this I get output that matches yours.

...
my $graph = Graph::Easy->new();
$graph->add_edge( split m{ -> } ) for keys %edges;
$graph->add_edge( 1, 2 );

print $graph->as_ascii();
[download]

I hope this is of interest.

---

---

Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!

Titles consisting of a single word are discouraged, and in most cases are disallowed outright.

Read Where should I post X? if you're not absolutely sure you're posting in the right place.

Please read these before you post! —

• How do I compose an effective node title?
• How do I post a question effectively?
• Markup in the Monastery

Posts may use any of the Perl Monks Approved HTML tags:

a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr

You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)

	For:		Use:
	&		&
	<		&lt;
	>		&gt;
	[		&#91;
	]		&#93;

Link using PerlMonks shortcuts! What shortcuts can I use for linking?

See Writeup Formatting Tips and other pages linked from there for more info.