Hello again Anonymous Monk,

You need to treat the pdf as binary file. For the moment I do not have the time to play with your script to modify it but here is a sample of code that I just tested and works with pdf attachment using MIME::Lite.

#!/usr/bin/perl
use strict;
use warnings;
use MIME::Lite;
use Getopt::Std;

my $SMTP_SERVER = '127.0.0.1';           # CHANGE ME
my $DEFAULT_SENDER = 'sender@example.com';      # CHANGE ME
my $DEFAULT_RECIPIENT = 'recipient@example.com';# CHANGE ME

MIME::Lite->send('smtp', $SMTP_SERVER, Timeout=>60);

my (%o, $msg);

# process options

getopts('hf:t:s:', \%o);

$o{f} ||= $DEFAULT_SENDER;
$o{t} ||= $DEFAULT_RECIPIENT;
$o{s} ||= 'Your binary file, sir';

if ($o{h} or !@ARGV) {
    die "usage:\n\t$0 [-h] [-f from] [-t to] [-s subject] file ...\n";
}

# construct and send email

$msg = new MIME::Lite(
    From => $o{f},
    To   => $o{t},
    Subject => $o{s},
    Data => "Hi",
    Type => "multipart/mixed",
    );

while (@ARGV) {
    $msg->attach('Type' => 'application/octet-stream',
         'Encoding' => 'base64',
         'Path' => shift @ARGV);
}

$msg->send( );

__END__

$ perl client.pl Documentation.pdf
[download]

Hope this helps, BR.