RSS is a bit of a mess —there are three versions, each fixing design flaws in the previous— so when I needed to generate a feed, I made it an atom feed.

I used XML::Atom::Syndication with these helpers: 

sub new_atom_obj {
   my $class = 'XML::Atom::Syndication::' . shift;
   ( my $file = $class ) =~ s{::}{/}g;
   $file .= '.pm';
   require($file);
   unshift @_, $class;
   goto &{ $class->can('new') };
}


sub set_fields {
   my $self = shift;
   while (@_) {
      my $field = shift;
      my $val   = shift;
      $self->$field($self, $val);
   }
   return $self;
}

[download]

The code looked like this: 

my $atom_dt_format = DateTime::Format::Atom->new();

my $feed_title       = ...;
my $feed_content_url = ...;

my $feed = set_fields( new_atom_obj('Feed'),
   title => set_fields( new_atom_obj('Text', Name => 'title'), type =>
+ 'text', body => $feed_title ),
   link  => set_fields( new_atom_obj('Link'), href => $feed_content_ur
+l ),
);

while (...) {
   my $entry_title       = ...;
   my $entry_content_url = ...;
   my $entry_pub_dt      = ...;
   my $entry_body        = ...;

   $feed->add_entry(
      set_fields( new_atom_obj('Entry'),
         title     => set_fields( new_atom_obj('Text', Name => 'title'
+), type => 'text', body => $entry_title ),
         link      => set_fields( new_atom_obj('Link', Name => 'link')
+, href => $entry_content_url ),
         published => $atom_dt_format->format_datetime($entry_pub_dt),
         content   => set_fields( new_atom_obj('Content'), type => 'ht
+ml', body => $entry_body),
      ),
   );
}

$feed->updated($atom_dt_format->format_datetime($feed_last_updated));

return $feed->as_xml();

[download]

In reply to Re: Recommendations for generating RSS feed? by ikegami
in thread Recommendations for generating RSS feed? by mldvx4

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.