The part you're asking about is actually fine. On the other hand, just about everything else looks wrong to me. Let's go over the code.

---

Always use use strict; use warnings qw( all );!!!

---

open TEST,"@ARGV[0]";
[download]

should be

open(my $TEST, "<", $ARGV[0])
   or die("Can't open \"$ARGV[0]\": $!\n");
[download]

• Use the safer three-arg open over the two-arg open.
• Always check open for errors as it is particularly prone to failure.
• Don't use global variables for nothing.
• Don't put variables in quotes for nothing.
• @ARGV[0] is an array slice, but you want to lookup a single value in the array.

---

$flag = "ON"
...
$flag = "OFF"
[download]

should be

my $looking = 1;
...
$looking = 0;
[download]

• Your code didn't even compile.
• Limit the scope of variables to where they are needed.
• Use true and false values (such as 1 and 0) for booleans instead of two true values (such as "ON" and "OFF").
• Use meaningful variable names.

---

while (<TEST>)
[download]

should be

while (<>)
[download]

<> is short for <ARGV>. ARGV is a specical file handle that reads from the files named in the argument list or STDIN if none.

---

if (/test/ and $flag eq "ON")
[download]

should be

if ($looking && /test/)
[download]

• It's better to only use the low precedence and, or and not for flow control (... or return ..., ... or die ..., ... or next ..., etc).
• When you want to test for truthness, don't check for a specific value.
• $looking is far cheaper than /test/, so we'll move it first.

---

print "start";
[download]

should be

print "start\n";
[download]

or

say "start";
[download]

---

close TEST;
[download]

is useless if you don't check if it succeeded.

---

So we now have

use strict;
use warnings qw( all );

my $looking = 1;
while (<>) {
   if ($looking && /test/) {
      print "start\n";
      $looking = 0;
   }
}
[download]

The one problem left is that you read "half" the file for nothing. Let's avoid that!

use strict;
use warnings qw( all );

while (<>) {
   if (/test/) {
      print "start\n";
      last;
   }
}
[download]

---

---

Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!

Titles consisting of a single word are discouraged, and in most cases are disallowed outright.

Read Where should I post X? if you're not absolutely sure you're posting in the right place.

Please read these before you post! —

• How do I compose an effective node title?
• How do I post a question effectively?
• Markup in the Monastery

Posts may use any of the Perl Monks Approved HTML tags:

a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr

You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)

	For:		Use:
	&		&
	<		&lt;
	>		&gt;
	[		&#91;
	]		&#93;

Link using PerlMonks shortcuts! What shortcuts can I use for linking?

See Writeup Formatting Tips and other pages linked from there for more info.